how to edit this vba code to create lines in excel

My last post was about editing a VBA code to create the header of a file that i’m using for electronic payments.
Today’s problem would be about modifying a code to create lines associated with the header.
So first, I’ll explain the format of the line :
The line is 62 characters long :

1. A star at the begining (*) of each line,
2. The account number which is 20 characters long (no more than that), for example if a cell in excel contains the account number, let’s say 300034 and another cell contains the key associated with the account, let’s say 70, the line to this stage woulld be *00000000000030003470.
3. the amounts that a client will receive, (no more than 13 characters), for example if a cell contains 30759.25, than the line until now would look like this :
   *000000000000300034700000003075925
   If the amount is 99999999999.99 then the line would look like this :
   *000000000000300034709999999999999
4. the name of the client (no more than 27 characters), if the name is joseph david, it means that there is 12 characters including the space between « joseph » and « david », so the line created thus far would look like this :
   *000000000000300034709999999999999joseph david 1
   With 15 spaces after david to each 27 characters, and then the number (1) at the end of the line to reach 62 characters of the line.
   The code that i have does not limit the size of names, accounts, amounts.
   The code is :

   Public Function Lines(Account, Key, Amount, Name As String) As String
   
   'Account
   C1 = Len(Account)
   C1 = (18 - C1)
   For i = 1 To C1
   M = M & "0"
   Next
   C1 = M & Account
   
   'Key
   If Key = "" Then
      Key = "00"
   ElseIf Key < 10 Then
      Key = "0" & Key
   Else
      Key = Key
   End If
   
   'Amount
   Amount = Amount * 100
   C2 = Len(Amount)
   C2 = (13 - C2)
   For i = 1 To C2
   M1 = M1 & "0"
   Next
   C2 = M1 & Amount
   
   'Nen & PréName
   C3 = Name
   
   'Annee
   C4 = "*" & C1 & Key & C2 & C3
   
   'CD ZERO
   C5 = Len(C4)
   C5 = (61 - C5)
   For i = 1 To C5
   M3 = M3 & " "
   Next
   C5 = C4 & M3
   
   Lines = C5 & "1"
   
   End Function
   

thanks in advance

Try the following code:

Public Function Lines(Account As String, Key As String, Amount as Double, Name As String) As String
    Const accountLen = 20
    Const amountLen = 13
    Const nameLen = 27

    Lines = "*" _
          & Right(String(accountLen, "0") & Account & Key, accountLen) _
          & Format(Amount * 100, String(amountLen, "0")) _
          & Left(Right(Name, nameLen) & String(nameLen, " "), nameLen) _
          & "1"
End Function

The String function creates a String that contains a number of characters, eg String(20, "0") creates a string "00000000000000000000".

For the Account, we concatenate this 20 zeros with the account and the key and take the rightmost 20 characters - that gives the account & key with leading zeros.

For the Amount, I assume we have a numeric value, and we can use the Format function to create leading zeros and 2 decimals. Update: Changed this as OP don't want decimal comma (or point).

For the Name, we take the rightmost 27 characters plus 27 spaces and take 27 characters from the left of the result - that gives the name with trailing blanks.