zsh basename and ${var%.*}

How to understand the different output between file2 and file3?

(base) ➜  Youtube cat 1.sh
base="/VS/Harry Potter - Hedwig's Theme (Harmonica Ver.) [w2kuM-Rp_IY].info.json"
echo "base:  $base";
dir=$(dirname "$base");
filename=$(basename "$base");
file=${${filename%.*}%.*};
file2=${${"$(basename $filename)"%.*}%.*};
file3=${${$(basename $filename)%.*}%.*};
echo "file:  $dir/$file";
echo "file2: $dir/$file2";
echo "file3: $dir/$file3";

(base) ➜  Youtube zsh 1.sh
base:  /VS/Harry Potter - Hedwig's Theme (Harmonica Ver.) [w2kuM-Rp_IY].info.json
file:  /VS/Harry Potter - Hedwig's Theme (Harmonica Ver.) [w2kuM-Rp_IY]
file2: /VS/Harry Potter - Hedwig's Theme (Harmonica Ver.) [w2kuM-Rp_IY]
file3: /VS/Harry Potter - Hedwig's Theme (Harmonica Ver [w2kuM-Rp_IY]

It seems basename command returns a serval part split by space and ${var%.*} command works on each part.

>It seems basename command returns a serval part split by space and ${var%.*} command works on each part.

Pretty much, yes.

From the documentation on command substitution:

>If the substitution is not enclosed in double quotes, the output is broken into words using the IFS parameter.

And from the section on parameter expansion talking about pattern deletion and substitutions:

>... when name is an array and the substitution is not quoted, or if the (@) flag or the name[@] syntax is used, matching and replacement is performed on each array element separately.

So that's the situation you're running into with the unquoted command substitution. Its output is broken up into words and each word is checked for a matching pattern to delete.

You didn't quote the $( command substitution ) so it got split by IFS characters and treated like an array value by subsequent nested ${} parameter expansions. Being array valued, the ${param%pattern} expansion was applied to each element. Then the result was joined by the first character of IFS due to file3=... being a scalar assignment. This would have happened to the output from any command - it is not specific to basename. The effect would have been more noticeable had the input string contained >1 type of IFS character or >1 sequential IFS character.

In zsh you may use the t (tail) or h (head) expansion modifiers, rather than external basename or dirname tools.

The r (root) modifier seems to be a better fit for your use case of chomping off the "extension" part:

base="/VS/Harry Potter - Hedwig's Theme (Harmonica Ver.) [w2kuM-Rp_IY].info.json"
file4=$base:r:r
typeset -p file4

It will only act on the tail of the path, so you don't need to do your own split->modify->join processing. file4=$base:F[2]r is another option instead of doubling the :r. That is the F:expr: modifier to repeat the following r modifier 2 times.