Google Sheets - Add value of cells until it reaches X or Y values, then return answer for X or Y

I'm using Google Sheets and I'm trying to figure out how to write the logic for something difficult to explain.

Col 1 starts to compile a sum count from rows 1-5; If the sum is >= X it should output "Success"; If the sum <= Y it should output value "Fail".

For example, sum cells Row 1, Col 01 -> Row 5, Col 1 until sum reaches >= "4". If it reaches 4, the summing should stop and output "Success" AND if summing results in reaching <= -1 it should stop and output "Fail".

I'd like to apply this to many different rows within the data table. Hopefully you can understand where I'm going with this. Thanks.

     Col 01
1    1            
2    2
3    -3 
4    4
5    -2         

SCAN lets you run cumulative sums. For example:

=SCAN(0, TOCOL(A2:A,1),LAMBDA(a,v,  a+v ))

It returns the value of the cumulative sum, because it sums the previous value (a) with the new one (v). Now you only need to add the IF statements:

=SCAN(0,TOCOL(A2:A,1),LAMBDA(a,v,
IF(a+v>=4,"Success",IF(a+v<=-1,"Fail",a+v))))

Now, after Success or Fail, the cumulative sum will stop since it's not possible to add to a string. That's why you can add IFERROR to empty those values, and TOCOL optionally if you want to narrow the results exactly to those cells:

=TOCOL(IFERROR(SCAN(0,TOCOL(A2:A,1),LAMBDA(a,v,IF(a+v>=4,"Success",IF(a+v<=-1,"Fail",a+v))))),1)

So, with only one formula in B2 you get this result:

This is definitely the long way to do it, but here is my answer:
In column A, you put all your data.
In B1, put in this: (change A1:A5 based of range of data)

=MAP(A1:A5, LAMBDA(val, IF(CELL("row", val)=1,A1,SUM(INDIRECT("A1:"&ADDRESS(IF(CELL("row", val) - 1<1, 1, CELL("row", val) - 1),CELL("col", val),4))))))

This essentially puts in column B the sum of everything above the cell in column A.
In this next part, say that cell D2 is the minimum value, and E2 is the maximum value.
In column C, C1 is going to be:

=IF(B1>=E2,"SUCCESS",IF(B1<=D2,"FAIL",""))

this sets it to SUCCESS and FAIL if the conditions are met.
On all the subsequent rows in column C, enter in:

=IF(INDEX(A:Z,ROW()-1,COLUMN())="",IF(INDEX(A:Z,ROW(), COLUMN()-1)>=E2,"SUCCESS",IF(INDEX(A:Z,ROW(), COLUMN()-1)<=D2,"FAIL",""))," ")

This does the same as the first column, but does not set the cell to success or fail if one above has already done so.
Optionally, in a different cell you can put: (change C1:C5 based on range of data)

=SWITCH(SUM(MAP(C1:C5,LAMBDA(val, SWITCH(val, "SUCCESS", 1, "FAIL", -1, "", 0, " ", 0, 2)))),1,"SUCCESS", 0, "", -1,"FAIL", "ERROR")

This tells you if any of them at all got labeled as success or fail.
Here the final product: