Best way to define dynamic block device selection in Terraform

I'm trying to go off of the solution accepted in https://stackoverflow.com/questions/75257194/format-ascii-number-to-ascii-character-in-terraform but am still a bit confused how to go about the following:

Your example suggests that your goal is to map from an integer to a letter to use as a device name for an EC2 volume attachment. I think the most straightforward answer to meet that need with Terraform would be to hand-write (or, if you wish, use a one-off script to generate) a lookup table:

locals {
  device_names = tolist([
    "xvda",
    "xvdb",
    "xvdc",
    "xvdd",
    # (and so on for however many devices you expect to need to support,
    # presumably up to "z" at the worst)
  ])
}

So, my situation is that I will have to use the same TF module to spin up EC2s that require different numbers of block devices. Some larger than others. So let's say I have a lookup table that has device names from "/dev/sda, /dev/sdb, ... all the way to /dev/sdz." I'm still struggling to connect how to use an integer to say I want 6 block devices, and then get "/dev/sda, /dev/sdb, /dev/sdc, /dev/sdd, /dev/sde, /dev/sdf" as a result.

My intention would be to have a *.tf input file that would override default variables in order to get my desired result. So, for example, I might have a variable called data_file_count = 6. With that, I would hope to get my six block devices provisioned. In a subsequent run of the same module, I may have a different *.tf input file that sets data_file_count = 12 and get my 12 block devices provisioned for the EC2 instance...

Trying to find a lean and concise way to accomplish this... appreciate any help!

Thanks,
Steve

First of all, as the original answer says, you have to specify a list with the device names. You have to make sure that you have enough elements in the list. If you expect 12 devices, you have to specify at least 12 names in the list:

locals {
  device_names = tolist([
    "/dev/sda",
    "/dev/sdb",
    "/dev/sdc",
    "/dev/sdd",
    "/dev/sde",
    "/dev/sdf",
    "/dev/sdg",
    "/dev/sdh",
    "/dev/sdi",
    "/dev/sdj",
    "/dev/sdk",
    "/dev/sdl"
    # (and so on for however many devices you expect to need to support,
    # presumably up to "z" at the worst)
  ])
}

Second, as you said, you have to declare a variable for the number of devices you want to attach to an instance. I will call this variable number_of_devices, you may call it however you want.

variable "number_of_devices" {
  type    = number
  default = 6 # optional default value
}

Now, in order to get a sublist with the names, we can use the slice function from terraform.

For example:

output "devices" {
  value = slice(local.device_names, 0, var.number_of_devices)
}

Assuming the value for number_of_devices is 6, we will get the following result:

devices = tolist([
  "/dev/sda",
  "/dev/sdb",
  "/dev/sdc",
  "/dev/sdd",
  "/dev/sde",
  "/dev/sdf",
])

Now, the trickiest part. In order to use this sublist to actually have as many devices as you need, you can use a dynamic block from Terraform. For example:

resource "aws_instance" "this" {
  ami           = ...
  instance_type = "t4g.nano"
  tags = {
    Name = "test"
  }

  dynamic "ebs_block_device" {
    for_each = slice(local.device_names, 0, var.number_of_devices) # notice the sublist with the names
    content {
      device_name = ebs_block_device.value
    }
  }
}

Keep in mind, this code was meant to be just an example of how to use the a dynamic block. In order to provision an EC2 instance, you may want to configure a bunch of other stuff and also you may want to avoid device naming collision with the root device.