Unique ID being changed when deserializing JSON - it should stay the same

I have a small class in which when the constructor is fired it generates a new unique ID. However, when I serialize it and then deserialize it my ID is being generated again because it seems to be creating a new object again. What is the easiest way to stop this behavior? (I would like to keep the unique guid generation in the constructor if possible)

 <Serializable>
    Public Class YubikeyPool
        Public ReadOnly Property ID As Guid
        Public Property Name As String

        Public Sub New()
            ID = Guid.NewGuid()
        End Sub
       
        Public Overrides Function ToString() As String
            Return Name
        End Function
    End Class

Here is my Serialize/Deserialize functions

 Function Serialize(ByVal objData As Object) As Byte()
    If objData Is Nothing Then Return Nothing
    Return Encoding.UTF8.GetBytes(JsonSerializer.Serialize(objData, GetJsonSerializerOptions()))
End Function

Function Deserialize(Of T)(ByVal byteArray As Byte()) As T
    If byteArray Is Nothing OrElse Not byteArray.Any() Then Return Nothing
    Return JsonSerializer.Deserialize(Of T)(byteArray, GetJsonSerializerOptions())
End Function

Private Function GetJsonSerializerOptions() As JsonSerializerOptions
    Dim options = New JsonSerializerOptions
    With options
        .PropertyNamingPolicy = Nothing
        .WriteIndented = True
        .AllowTrailingCommas = True
        .DefaultIgnoreCondition = JsonIgnoreCondition.WhenWritingNull
    End With

    Return options
End Function

The constructor WILL run. The only way to keep a prior value is to overwrite the constructor's work and the set the value along with other properties when you deserialize... which can't happen right now because the property is marked ReadOnly. Start by removing that modifier.

You can probably make a little change to your class definition, using an overloaded Constructor and decorating the default Constructor with [JsonConstructorAttribute]

The read-only property (here, the property has a private setter) can be decorated with a [JsonIncludeAttribute]. In this case, the non-public setter is used. For example:

(in C#, since you have tagged this language)
Assuming System.Text.Json 7.0.0.3

[Serializable]
public class YubikeyPool {
    [System.Text.Json.Serialization.JsonInclude]
    public Guid ID { get; private set; }

    public string Name { get; set; }

    [System.Text.Json.Serialization.JsonConstructor]
    public YubikeyPool() : this(string.Empty) { }

    public YubikeyPool(string name) => ID = Guid.NewGuid();

    public override string ToString() => Name;
}

You can initialize a class object as you were probably doing.

var yp = new YubikeyPool() { Name = "Some Name" };

The previously auto-generated GUID is preserved when deserializing

I think the method used for serialization should be changed in:

public byte[] Serialize<T>(T objData) where T : class {
    if (objData is null) return null;
    return Encoding.UTF8.GetBytes(JsonSerializer.Serialize(objData, GetJsonSerializerOptions()));
}

VB.NET version:

<Serializable>
Public Class YubikeyPool
    Private m_ID As Guid

    <JsonInclude>
    Public Property ID As Guid
        Get
            Return m_ID
        End Get
        Private Set()
            m_ID = Value
        End Set
    End Property

    Public Property Name As String

    <JsonConstructor>
    Public Sub New()
        Me.New(String.Empty)
    End Sub

    Public Sub New(name As String)
        Me.Name = name
        ID = Guid.NewGuid()
    End Sub

    Public Overrides Function ToString() As String
        Return Name
    End Function
End Class

Public Function Serialize(Of T As Class)(objData As T) As Byte()
    If objData Is Nothing Then Return Nothing
    Return Encoding.UTF8.GetBytes(JsonSerializer.Serialize(objData, GetJsonSerializerOptions()))
End Function