Macro in excel to implement a "+" button for N items. how to create only one macro but increment all items individually?

I created an macro in excel and associated it to a button. Basically, the macro implements a "+" button, which, as the name suggests, increments a counter variable in a cell (say the cell is B1). For instance, if I click twice on the button, B1 stores the value 2, and so on.

I have a longer list of items for which I need this "+" button (N items -> N buttons to increment the items individually). Is there a solution to not create a macro for all N items?

EDIT:

This is how my macro currently looks like:

Sub add_1()
    Range("B1").Value = Range("B1").Value + 1
End Sub

I launch this macro from a button in cell "A1". I also want to have a button in "A2", which increments the value in cell "B2", and so on.

Lets say you have headers in row 1 and you want your plus-button in column C, then the following code will help you.

Option Explicit

Sub add_buttons()
Dim btn As Button
Dim i As Long, last As Long
Dim rng As Range
last = Cells(Rows.Count, 2).End(xlUp).Row
Application.ScreenUpdating = False
ActiveSheet.Buttons.Delete
For i = 2 To last
    If Cells(i, 2) <> "" Then
        Set rng = Cells(i, 3)
        Set btn = ActiveSheet.Buttons.Add(rng.Left, rng.Top, rng.Width, rng.Height)
        With btn
            .OnAction = "btn_plus"
            .Caption = "+"
            .Name = "btn_plus_" & i
        End With
    Else
        Exit For
    End If
Next i
Application.ScreenUpdating = True
End Sub

Sub btn_plus()
Dim i As Long
If Left(Application.Caller, 8) = "btn_plus" Then
    i = CInt(Mid(Application.Caller, InStrRev(Application.Caller, "_") + 1))
    Cells(i, 2) = Cells(i, 2) + 1
End If
End Sub

The first sub add_buttons add buttons next to every value in column B. The second sub btn_plus, adds +1 to the cell next to the button that is clicked on.

I have created this macro:

Sub Increase()
ActiveCell.Value = ActiveCell.Value + 1
End Sub

... and added a commandbutton, launching this macro, when clicked.

I selected cell "B2", entered the number 5 and clicked two times.
Then I selected cell "B3" and clicked two times:

Resulting screenshot: