How can I resolve this Error in refedit in excel VBA

When I select a cell in an excel sheet by a refedit and click on the arrow button in the following form:

and then click on the button again in that refedit

and select a cell, in the box there will be two cells that between them there is no comma(Although the address of the first cell sometimes changes to the second cell but usually the address of the first cell is not deleted):

and if I want to use this string as a range , this cause an Error. How can I solve this problem? By some addition code? or
Does my excel-2016 have a problem?

If I could clear the refedit when the small window appear, that was very good. But the codes refedit.value="" or refedit.delete do not work.

Private Sub RefEdit1_Change()

Dim ra11 As Range
Set ra11 = Range(RefEdit1.Value)
k = ListBox8.ListCount
Dim ra22 As Range
For Each ra22 In ra11
    ListBox8.AddItem
    ListBox8.List(k, 0) = sh2.Cells(ra22.Row, rff1p_s.Column)
    ListBox8.List(k, 1) = sh2.Cells(ra22.Row, icolsar1p(14))
    k = k + 1
Next ra22

End Sub

The RefEdit control in VBA has historically had the issue. The following Exit event code attempts to clean the text (range reference) when it is wrong. I hope the code is helpful.

Private Sub RefEdit1_Exit()
    Ref = Me.RefEdit1.Text
    If VBA.InStr(Ref, ",") = 0 Then
        If Len(Ref) - Len(Replace(Ref, "!", "")) >1  Then Me.RefEdit1.Text = ""
    Else
        For Each subRef In Split(Ref, ",")
            If Len(subRef) - Len(Replace(subRef, "!", "")) >1  Then
                Me.RefEdit1.Text = ""
                Exit For
            End If
        Next
    End If
End Sub

Following my comment, will add a workaround to avoid using a glitchy RefEdit control.

Prerequisites.
Controls:
-UserForm
-TextBox
-CommandButton

Variables:
-rangeToSet As Range - main range to be assigned
-inptResult As Range - InputBox result variable to perform the selection check
-isRangeSelected As Boolean - module global boolean variable for further checks

Usage:
Press the button and select range

The code:

Option Explicit

Dim isRangeSelected As Boolean

Private Sub selectRangeButton_Click()
Dim rangeToSet As Range
Dim inptResult As Range

Me.rangeTextBox.Text = ""

On Error Resume Next
Set inptResult = Application.InputBox(Prompt:="Select range", Type:=8)
Err.Clear
On Error GoTo 0


If Not inptResult Is Nothing Then
    Set rangeToSet = inptResult
    isRangeSelected = True
    Me.rangeTextBox.Text = rangeToSet.Address
Else
    Me.rangeTextBox.Text = "The range is not selected"
    isRangeSelected = False
End If

End Sub