Terraform - How to combine three lists together to build a list of maps

I wrote code as below to flatten a list of lists, but it’s not producing me the expected results.

locals {

    alarms = {
        names = ["NumberOfMessagesReceived", "NumberOfMessagesDeleted", "ApprNumberOfMessagesDelayed",
                 "NumberOfMessagesSent", "NumberOfEmptyReceives", "ApprNumberOfMessagesNotVisible"],

        thresholds = ["1000", "50", "100", "100", "100", "50"]
    }

    sqs_queues = {
        queues = ["default", "general"]
    }

    alarms2 = flatten([

        for name, threshold in local.alarms : [

            for sqs_queue in local.sqs_queues : {

                alarm_name = name
                threshold_value = threshold
                sqs_queue_name = sqs_queue

            }

        ]

    ])
}

The expected output is,

alarm_name = "NumberOfMessagesReceived"
threshold_value = "1000"
sqs_queue_name = ""default"

alarm_name = "NumberOfMessagesReceived"
threshold_value = "1000"
sqs_queue_name = ""general"

The alarm name should be associate with corresponding threshold. And every combination of alarm name and threshold should be associated with each sqs_queue...

You can use setproduct to generate all possible combinations between local.alarms.names and local.sqs_queues.queues, and by iterating over the result you can use the index to access the threshold value corresponding to the name:

locals {

  alarms = {
    names = ["NumberOfMessagesReceived", "NumberOfMessagesDeleted", "ApprNumberOfMessagesDelayed",
    "NumberOfMessagesSent", "NumberOfEmptyReceives", "ApprNumberOfMessagesNotVisible"],

    thresholds = ["1000", "50", "100", "100", "100", "50"]
  }

  sqs_queues = {
    queues = ["default", "general"]
  }

  alarms2 = [
    for i,v in setproduct(local.alarms.names,local.sqs_queues.queues) : {
      alarm_name = v[0]
      threshold_value = element(local.alarms.thresholds,index(local.alarms.names,v[0]))
      sqs_queue_name = v[1]
    }
  ]
}

$ terraform console
> local.alarms2
[
  {
    "alarm_name" = "NumberOfMessagesReceived"
    "sqs_queue_name" = "default"
    "threshold_value" = "1000"
  },
  {
    "alarm_name" = "NumberOfMessagesReceived"
    "sqs_queue_name" = "general"
    "threshold_value" = "1000"
  },
  {
    "alarm_name" = "NumberOfMessagesDeleted"
    "sqs_queue_name" = "default"
    "threshold_value" = "50"
  },
  {
    "alarm_name" = "NumberOfMessagesDeleted"
    "sqs_queue_name" = "general"
    "threshold_value" = "50"
  },
  ...

In Terraform, you can combine lists together by using the concat function. This function concatenates multiple lists into a single list.

Here's an example of how you can use it:

variable "list1" {
  default = ["item1", "item2", "item3"]
}

variable "list2" {
  default = ["item4", "item5", "item6"]
}

variable "list3" {
  default = ["item7", "item8", "item9"]
}

output "combined_list" {
  value = concat(var.list1, var.list2, var.list3)
}

In this example, list1, list2, and list3 are variables holding different lists. The concat function is used in the combined_list output to merge all three lists into one.

When you run terraform apply, the combined_list output will display the combined list:

combined_list = [  "item1",  "item2",  "item3",  "item4",  "item5",  "item6",  "item7",  "item8",  "item9",]

This is a straightforward way to combine lists in Terraform. You just have to ensure that all the lists you want to combine are of the same type, as Terraform does not support lists with mixed types.