Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   Dim v As Variant
   If Target.CountLarge = 1 Then
      'If Target.Address = Range("A1").Address Then
      If Target.Column = 1 Then  ' all cells in column 1  (A)
         v = getRandomValue(Target, Me)
         If v <> vbNullString And v <> Target.Value2 Then
            Application.EnableEvents = False
            Target.Value2 = v
            Application.EnableEvents = True
         End If
      End If
   End If
End Sub
' GET A VALUE FROM A RANDOM CELL, OF CELL's VALIDATION LIST
Public Function getRandomValue(r As Range, ws As Worksheet) As Variant
   Dim s As String, ir As Range
   
   getRandomValue = vbNullString
   If hasValidationList(r) Then
      s = Trim(r.Validation.Formula1)
      Set ir = ws.Range(Trim(Mid(s, 2)))
      getRandomValue = ir.Cells(WorksheetFunction.RandBetween(1, ir.CountLarge)).Value2
   End If
End Function
' HELPER FUNCTION - CHECK IF A CELL HAS VALIDATION LIST
Public Function hasValidationList(r As Range) As Boolean
   Dim t As XlDVType
   On Error Resume Next
   t = r.Validation.Type
   On Error GoTo 0
   hasValidationList = (t = xlValidateList)
End Function
' AN EXAMPLE TO FILL ANY CELLS IN A1:A1000 WHITCH HAVE A VALIDATION LIST
' WITH A RANDOM VALUE FROM THEIR LIST
'COPY THIS IN THE SHEET'S MODULE  (NO IN A COMMON MODULE)
Private Sub fillAllCellsRandomly()
   Dim lastRow As Long, rng As Range, rr As Range, v As Variant
   lastRow = 1000
   Set rng = Me.Range("A1:A" & lastRow)
   For Each rr In rng
      v = getRandomValue(rr, Me)
      If v <> vbNullString Then rr.Value2 = v
   Next
End Sub