Convert UTC to Location specific time in Perl

I have written a script, which takes UTC time as an input and should print location specific (site id) time. The site id is been hard-coded as of now, which will vary according to the site.

Below is my script:

#!/usr/bin/env perl5.34.0

use strict; use warnings;
use Date::Parse;
use DateTime;
use Time::Piece qw( localtime );
use POSIX 'strftime';
use Date::Format qw(!strftime);

my $site_id = 1;

my %time_zone_hash = (
                1 => 'Europe/London', #london (GMT+0)
                2 => 'Asia/Kolkata', #bang (GMT+05:30)
        );

my $utc_now = strftime('%Y-%m-%d %H:%M:%S', gmtime());
print "UTC:$utc_now\n";

my $site_time = convertSiteTime($site_id, $utc_now);
print "site_time=$site_time\n";
print time2str('%Y-%m-%d %H:%M:%S', $site_time)."\n";

sub convertSiteTime {
        my $id = shift;
        my $time_str = shift;
        my $epoch_time = str2time($time_str);

        if (!$epoch_time) {
                print "$time_str is not a valid date. Please provide a valid date.\n";
                exit(1);
        }
        my $dt = DateTime->from_epoch(epoch => $epoch_time);
        $dt->set_time_zone($time_zone_hash{$id});

        return $dt->epoch();
}

Output:

UTC:2023-07-20 09:19:16
site_time=1689824956
2023-07-20 09:19:16

It gives same result for UTC and site time. The site time suppose to be 2023-07-20 10:19:16 in this scenario.

Could someone please let me know whats wrong in the script.
Also my system (environment) is set to UTC time.

You are asking how to convert a date-string from UTC to another time zone (Asia/Kolkata).

Your flow:

string -> epoch -> DT object -> change time zone -> epoch -> string

Converting a date-time from one time zone to another has no effect on epoch. It doesn't matter where you are on Earth, the same amount of time has passed since 1970-01-01T00:00:00Z.^[1]

That means that

my $dt = DateTime->from_epoch(epoch => $epoch_time);
$dt->set_time_zone($time_zone_hash{$id});
return $dt->epoch;

is the same as

return $epoch_time;

Since that whole middle bit is useless, your flow is effectively the following:

string -> epoch -> string

This is actually correct. Also correct:

string -> object -> string

The problem is that you are doing those conversions incorrectly.

I'll start with repeating the DateTime and Time::Piece solutions I already provided in my answer to your earlier question, then I'll provide a Date::Parse + Date::Format solution.

Converting a date-string from UTC to another time zone using DateTime

use DateTime::Format::Strptime qw( );

my $format = DateTime::Format::Strptime->new(
   pattern   => "%F %T",
   strict    => 1,
   time_zone => "UTC",
   on_error  => "croak",
);

my $dt = $format->parse_datetime( "2023-07-20 09:19:16" );
$dt->set_time_zone( "Asia/Kolkata" );
say $dt->strftime( "%F %T %z" );

2023-07-20 14:49:16 +0530

• Doesn't rely on %ENV.
• Doesn't rely on the system for its definitions of time zones.
• Not included with perl.
• Relatively slow.
• Decent interface.

Converting a date-string from UTC to another time zone using Time::Piece

use Time::Piece qw( localtime );

my $dt;

{
   local $ENV{ TZ } = "UTC";
   $dt = localtime->strptime( "2023-07-20 09:19:16", "%F %T" );
}

{
   local $ENV{ TZ } = "Asia/Kolkata";
   say $dt->strftime( "%F %T %z" );
}

2023-07-20 14:49:16 +0530

• Even temporary changes to %ENV might be problematic in a threaded application.
• Relies on the system for its definitions of time zones, so it might be less portable.
• Included with Perl.
• Fast.
• Time::Piece can be very tricky to use correctly.

Converting a date-string from UTC to another time zone using Date::Parse + Date::Format

I've just discovered the handling of time zones by those modules is complete garbage.

Since we know the offset of the input, we can Date::Parse's str2time. But we can't use Date::Format's time2str to get the desired output.

1. Aside from relativistic effects.