CMake POST_BUILD custom command ignores file dependencies

I want to run a script every time my project has been built, but also if any of the dependency files have changed. Right now I have:

add_custom_command(
	TARGET kernel POST_BUILD
	# doesn't work :(
	DEPENDS build-iso.sh limine.cfg
	BYPRODUCTS ${CMAKE_BINARY_DIR}/kernel.iso
	COMMAND ./build-iso.sh $<TARGET_FILE:kernel> ${CMAKE_BINARY_DIR}/kernel.iso ${CMAKE_BINARY_DIR}/iso_root
	WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
	VERBATIM
)

It works fine if I edit any of the source code, but if I only change something on limine.cfg, the command isn't ran on cmake --build build

As the documentation says,

> The command becomes part of the target and will only execute when the target itself is built. If the target is already built, the command will not execute.

<sup>See: https://cmake.org/cmake/help/latest/command/add_custom_command.html#build-events&lt;/sup>

So it does not matter that limine.cfg was modified because kernel wasn't built.

POST_BUILD plus BYPRODUCTS is usually a sign that you want OUTPUT with a dependency on that target, plus a custom target to drive the OUTPUT command. Something like this:

set(kernel_iso "${CMAKE_CURRENT_BINARY_DIR}/kernel.iso")
set(iso_root "${CMAKE_CURRENT_BINARY_DIR}/iso_root")
set(build_script "${CMAKE_CURRENT_SOURCE_DIR}/build-iso.sh")

add_custom_command(
    OUTPUT "${kernel_iso}"
    COMMAND "${build_script}" "$<TARGET_FILE:kernel>" "${kernel_iso}" "${iso_root}"
    DEPENDS
      "${build_script}"
      limine.cfg
      kernel  # File-level dependency on `kernel`.
    WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
    VERBATIM
)

add_custom_target(kernel_iso ALL DEPENDS "${kernel_iso}")

Note that the $<TARGET_FILE:kernel> generator expression implicitly adds a target-level dependency on kernel, but not a file-level dependency. This would mean that building kernel_iso would not bring kernel up to date. By naming kernel in DEPENDS, we establish the necessary file-level dependency.