Mismatch error 13 in Ubound when entering a single value

My code works how I want it to work, but when I have to put a single value, it shows error 13, and I don't really know why. I think it is because you can't use ubound in a single value array, but I don't know how to solve or replace it

I tried using an If that when I have a single value it just uses another variable, but it didn't work, and I don't really think that's a solution.

 Dim material As Variant, cantidad As Variant
    Dim g As Long, lastrow As Long, cant As Long
    Dim wsCarg As Worksheet, wsRem As Worksheet, wb As Workbook, wsDev As Worksheet
   
   
    Set wb = ThisWorkbook 'for example
    Set wsCarg = wb.Worksheets("CARGA")
    Set wsRem = wb.Worksheets("REMITO")
    Set wsDev = wb.Worksheets("DEVOLUCIONES")
    
    lastrow = wsRem.Cells(Rows.Count, "C").End(xlUp).Row
    material = wsRem.Range("C28:C" & lastrow).Value
    cantidad = wsRem.Range("M28:M" & lastrow).Value
    g = UBound(material, 1) 'number of rows of data

This is the part of the code which has an error, if you can suggest anything I will appreciate it, sorry for my English, and thanks in advance!

Range.Value returns always a 2-dimensional array with the values (even if you have only one row or one column of data). Except if the range contains only one cell, in that case it simply returns the value itself (not as array).

There are many ways to check this:

Use the property Count (or, even better CountLarge to avoid overflows) of the range. Note that this will work only correctly if you have only one Column as it counts the total number of cells of the range (rows * columns)

g = wsRem.Range("C28:C" & lastrow).CountLarge

You can use the Rows.Count-property of the Range

g = wsRem.Range("C28:C" & lastrow).Rows.Count

You could compare lastrow with the starting row. I would suggest to use a constant definition:

Const startRow = 28
material = wsRem.Range("C" & startRow & ":C" & lastrow).Value
g = lastRow - startRow + 1

You can check if the returned value is an array:

If IsArray(material) Then 
    g = UBound(material, 1)
Else
    g = 1
End If

However, when you process the data (eg material), it might come handy to convert it to a 2-dimensional array with 1*1 elements when it contains only a single value. With that, you don't have to take care if you deal with an array or not in the following code, eg

If Not isArray(material) Then
    Dim tmpVal As Variant
    tmpVal = material
    Redim material(1 to 1, 1 to 1)
    material(1, 1) = tmpVal
End If