SED INSERT block of code BEFORE matched block

I have a text file I want to edit during a script excecution.
I want to pass from the text on left to the text on right using sed insert:

INSERT BEFORE:
from:

[...]
[ placeholder ]
Categ         #n
ItemName      1
[...]
[ placeholder ]
Categ         #n
ItemName      2
[...]

to:

[...]
[ placeholder ]
Categ         #n
ItemName      1
[...]
**new_line1**        <<<--- INSERT BEFORE
**new_line2**        |||
**new_line3**        |||
[ placeholder ]      <<<--- 3-lines match
Categ         #n     |||
ItemName      2      |||
[...]

I have tried to adapt sed append lines to sed insert.
The appending works, the insert does not.
The match to append was 2 lines one after the other.
In the insert, the match it is 3 lines and I tried to match the first and the last, as I don't know how to match the entire 3-lines block.

APPEND AFTER:

sed -e '/^\[ placeholder \]\/ItemName      2/a \\nnew_line1\nnew_line2\nnew_line3' input.txt

and it works from:

[...]
[ placeholder ]
ItemName      1
[...]
[ placeholder ]
ItemName      2
[...]

to:

[...]
[ placeholder ]
ItemName      1
[...]
[ placeholder ]     <<<--- 2-lines match
ItemName      2     |||
**new_line1**       <<<--- APPENDED AFTER
**new_line2**       |||
**new_line3**       |||
[...]

I have tried to use the syntax examples in this post, but with no success.
The sed - Stream Editor

The problem becomes much simpler if the file is read backwards.

A sed solution is possible but awk is very straightforward:

tac input.txt |
awk '
    # copy every input line to output
    { print }

    # look for desired itemname line
    #   if found, change state and
    #   skip remaining tests (which can't match)
    $1=="ItemName" && $2==2 { s = 1; next }

    # if we get here, look for placeholder line
    #   if found, append new lines and reset state
    s && /\[ placeholder \]/ {
        print "new3"
        print "new2"
        print "new1"
        s = 0
    }
' | tac > output.txt

If your input does not contain NUL bytes you could try the following with GNU sed:

$ from='\[ placeholder \]\nCateg         #n\nItemName      2\n'
$ to='**new_line1**\n**new_line2**\n**new_line3**\n'
$ sed -Ez "s/(^|\n)($from)/$to/" input.txt
[...]
[ placeholder ]
Categ         #n
ItemName      1
[...]
**new_line1**
**new_line2**
**new_line3**
[ placeholder ]
Categ         #n
ItemName      2
[...]

With the -z option the input is treated as a set of lines, each terminated by a zero byte (the ASCII NUL character) instead of a newline. If the input does not contain NUL bytes this allows to process the entire file at once. Of course you must properly escape special characters in from and to.

A loop probably makes sense to accumulate the block into the pattern space:

sed '/placeholder/{:l /ItemName/!{N;bl};/ItemName.*2/s/^/new1\nnew2\nnew3\n/}' file 

Note that if ItemName is always two lines after placeholder then this simpler method also works:

sed '/placeholder/{N;N;/ItemName.*2/s/^/new1\nnew2\nnew3\n/}' file

There is also this complicated method of accumulating in the hold space rather than the pattern space:

sed '/placeholder/,/ItemName/{/placeholder/h;//!H;/ItemName/!d;//g;/ItemName.*2/s/^/new1\nnew2\nnew3\n/}' file

All methods produce this output:

[...]
[ placeholder ]
Categ         #n
ItemName      1
[...]
new1
new2
new3
[ placeholder ]
Categ         #n
ItemName      2
[...]

The simpler method is simply using N to append more lines into the pattern space before it's printed.

The loop adds a label :l and b branches to that label until ItemName.

The hold space method uses h and H to hold, d to delete and not print, g to get. As well as // as shorthand to repeat same match.

I have been lazy with the matches and the lines inserted to make this all more readable. ItemName.*2 is especially lazy. Probably should be something like ItemName\s\+2\b

This might work for you (GNU sed and bash):

match=''\[ placeholder \]\nCateg         #n\nItemName      2'
insert='**new_line1**\n**new_line2**\n**new_line3**'
sed '1N;N;/^'"${match}"'$/!{P;D};i\'"${insert}" file

Open a three line window until a match occurs, then insert the required string and thereafter the two line window will continue until the end of file.