VBA userform entry saves on wrong worksheet

I am having a problem regarding the location where my data entries get saved.

I have the code below for a button to add some entry on the worksheet "PL2_steel". The problem is that when the form loads, if instead of sheet "PL2_steel" another sheet is activated at that moment, it just saves the entry on the active sheet (and not on "PL2_steel").

Private Sub but_spl2addelement_Click()

    Dim sh As Worksheet
    Set sh = ThisWorkbook.Sheets("PL2_steel")
    
    Dim lr As Long
    lr = sh.Cells(Rows.Count, 1).End(xlUp).End(xlUp).Row
    
    Dim rng As Range
    Set rng = Sheets("PL2_steel").ListObjects("Tbl_spl2elements").DataBodyRange

    
            '''''''''''''''Validation'''''''''
            
    If txt_SPL2code.Text = "" Then
    MsgBox "Please assign a unique identifier code!", vbCritical
    Exit Sub
    End If
    
    With sh
        Cells(lr + 1, "A").value = Me.txt_SPL2code.value
        Cells(lr + 1, "B").value = Me.Combo_spl2elements.value
        Cells(lr + 1, "C").value = Me.txt_spl2gwp.value
        Cells(lr + 1, "D").value = Me.Txt_spl2count.value
        Cells(lr + 1, "E").value = Val(Me.Txt_spl2count.value) * Val(Me.txt_spl2gwp.value)
        Cells(lr + 1, "R").value = Val(Me.Txt_spl2count.value) * Val(Me.txt_spl2gwp.value)
    End With

        Me.Combo_spl2elements = ""
        Me.txt_spl2gwp.value = ""
        Me.Txt_spl2count.value = ""
       End Sub

I suppose I have declared the sheet properly. What could be the problem then?

The statement Cells() is handled as ActiveWorkbook.Cells() - To reference the Cells of a certain Worksheet you use ws.Cells() (In general the way you access properties or methods of an object is object.property or object.method

This also is true in With blocks. All the with does is: save you from having to type out the object you are referring to over and over again. So if you for example have the following code:

obj.property
obj.property
obj.property

you can use a with statement to avoid having to explicitly name obj every single time. - So you just wrap the statements into a with block and then remove obj from each line. You are then left with:

With obj
  .property
  .property
  .property
End With

The . signifies that this is the property/method of an object. If you didn't use the dot it would just be a normal variable.

For example see:

Dim name As String
name = "Julian"

With obj
  .name = name
  name = .surname
End With

Debug.Print obj.name 'Output: "Julian"
Debug.Print name 'Output: "" // provided obj.surname was not previously set to a value

For documentation on the With statement see here: https://learn.microsoft.com/en-us/office/vba/language/reference/user-interface-help/with-statement