find first and last visible row in specific range + border around range(first:last)

this seems to be a hard to find topic or my google skills left me once again.

I have a sheet, it has directions with numbers in Range(C31:C150)... e.g. C31:C55 has N10, N11, N12,... C56:C75 has S40, 41, 42, etc.. Depending on if the neighbour cell in column D is empty, the helper column BA contains a 1 if filled or 0 if empty. I then hide all rows containing a 0 in the column BA.
Because this is a dynamic process it often messes up the borders around the directions ranges (C31:C55;C56:C75;etc.).
In my example, only C31 from the first range is visible. In the 2nd range C56,57,60,63,64,65,72,73 are visible.
My goal is to get a border around C31 and C56:C73. actually its about getting a border around column C* to J*, but i guess or hope that i can do that "little" adjustment myself.

Anyone has an idea how i can approach this?

I found and tried these 2 approaches:

Sheets("sheet1").Range("C56:J75").SpecialCells(xlCellTypeVisible).BorderAround _
ColorIndex:=0, Weight:=xlMedium

this sadly splits the range into multiple areas, as soon as a hidden row is found (C56:C57;C60;C63:C65;C72:C73)
is there a way i can extract the row number of the upper and lower end? like left(56), right(73) and then combine both?

2nd approach was

Dim StartRow As Long, EndRow As Long
With Sheets("sheet1")
    StartRow = .Range("BA56:BA75").Find(what:=1, after:=.Range("BA56")).Row
    EndRow = .Range("BA56:BA75").Find(what:=1, after:=.Range("BA56"), SearchDirection:=xlPrevious).Row
End With

with the described example this gives me startrow 61?!?!?!??! WHat???
and endrow 71?!??! both hidden rows... but the code worked properly for C31 (i guess it only works with grouped data).

so while creating this question the automatic search found this:

Sub main()
    Dim firstCell As Range, lastCell As Range
    Set firstCell = first_non_blank_visible_cell(Range("$C$3:$C$5,$C$100:$C$64000"))
    Set lastCell = last_non_blank_visible_cell(Range("$C$3:$C$5,$C$100:$C$64000"))
    Debug.Print firstCell.Address
    Debug.Print lastCell.Address
End Sub

Function first_non_blank_visible_cell(rng As Range)
    On Error Resume Next
    Set rng = rng.SpecialCells(xlCellTypeVisible)
    Set rng = rng.SpecialCells(xlCellTypeConstants)
    With rng.Areas(1)
        Set first_non_blank_visible_cell = .Cells(1)
    End With
End Function

Function last_non_blank_visible_cell(rng As Range)
    On Error Resume Next
    Set rng = rng.SpecialCells(xlCellTypeVisible)
    Set rng = rng.SpecialCells(xlCellTypeConstants)
    With rng.Areas(rng.Areas.Count)
        Set last_non_blank_visible_cell = .Cells(.Cells.Count)
    End With
End Function

It worked at first, then i changed the range a second time for testing and it broke. cant get it back to work, not even in the range it used to work. lol. how is this possible

A bit trickier than I'd thought but still possible:

Sub DoBordersAroundVisibleRows()
    Dim rF As Range, rL As Range, rw As Range, el
    Dim ws As Worksheet
    
    Set ws = ActiveSheet
    Application.ScreenUpdating = False 'speed up
    ws.Range("C31:J128").Borders.LineStyle = xlNone
    
    'loop over each "block" in the range
    For Each el In Array("C31:J40", "C41:J55", "C55:J75", "C76:J95", _
                        "C96:J102", "C103:J114", "C115:J128")
        Set rF = Nothing 'reset first/last visible rows
        Set rL = Nothing
        For Each rw In ActiveSheet.Range(el).Rows 'loop rows in block
            If Not rw.EntireRow.Hidden Then       'row is visible?
                If rF Is Nothing Then             'first row gets a top border
                    Set rF = rw
                    ApplyBorders rF, xlEdgeTop
                End If
                Set rL = rw
                ApplyBorders rL, xlEdgeLeft, xlEdgeRight 'all rows get R/L borders
            End If
        Next rw
        If Not rF Is Nothing Then
            ApplyBorders rL, xlEdgeBottom 'last row gets bottom border
        End If
    Next el
End Sub

'Apply all borders supplied to `bordersToApply` to range `rng`
Sub ApplyBorders(rng As Range, ParamArray bordersToApply() As Variant)
    Dim i As Long
    For i = 0 To UBound(bordersToApply)
        With rng.Borders(bordersToApply(i))
            .LineStyle = xlContinuous
            .ColorIndex = xlAutomatic
            .TintAndShade = 0
            .Weight = xlMedium
        End With
    Next i
End Sub