Cell content upload when choosing dropdown menu option Word/VBA

So i got requested for:

a word file with a table in it where when picking an option in the drop down menu within a cell, another cell updates it's content.

i have the Drop down set uphere the drop down content control properties with names and values equalized

I have a plain text content control in the cell not much to be added here

when i enter the code

Sub UpdateContent()
    Dim dropdown As ContentControl
    Dim cell As ContentControl
    
    Set dropdown = ActiveDocument.SelectContentControlsByTitle("KörperTypen").Item(1)
    Set cell = ActiveDocument.SelectContentControlsByTitle("Klassifizierungen").Item(1)
    
    
    Select Case dropdown.DropdownListEntries(dropdown.Range.Text).Value
        
        Case "T1001"
            cell.Range.Text = "14C33242"
        Case "T2001"
            cell.Range.Text = "14C33342"
        Case "T3001"
            cell.Range.Text = "14C43342"
        Case "T4001"
            cell.Range.Text = "14C33342"
        Case "T5001"
            cell.Range.Text = "12C33342"
        Case "T6001"
            cell.Range.Text = "14C33342"
        Case "T7001"
            cell.Range.Text = "14C33342"

    End Select
End Sub

I get an error 13 type mismatch

the name of the cell, the plain text title, and the dropdown are correct.
i try to chang the values to number and retried with a numbering system, it gives me the same error, regardless of what i do.
If i try to look at the result of the dropdown.DropdownListEntries(dropdown.Range.Text).Value, it gives me the correct answer (ex "T1001"), still it does not run...
I trouble shooted and double checked multiples times, I believe it to be an extremely simple task, i'm just too ignorant to work it out myself.
I expect the cell to upload the contant of the plain text when picking the option in the drop down menú
What am i doing wrong?

When evaluating the value of a combo-box the DropdownListEntries are irrelevant. All you need to test is the text of the content control's range, as below.

Sub UpdateContent()
    Dim dropdown As ContentControl
    Dim cell As ContentControl
    
    Set dropdown = ActiveDocument.SelectContentControlsByTitle("KörperTypen").Item(1)
    Set cell = ActiveDocument.SelectContentControlsByTitle("Klassifizierungen").Item(1)
    
    
    Select Case dropdown.Range.Text
        
        Case "T1001"
            cell.Range.Text = "14C33242"
        Case "T2001"
            cell.Range.Text = "14C33342"
        Case "T3001"
            cell.Range.Text = "14C43342"
        Case "T4001"
            cell.Range.Text = "14C33342"
        Case "T5001"
            cell.Range.Text = "12C33342"
        Case "T6001"
            cell.Range.Text = "14C33342"
        Case "T7001"
            cell.Range.Text = "14C33342"

    End Select
End Sub