Error in Summarizing Row Data and Threaded Comments in Another Sheet

In a sheet containing student data, I'm trying to automate taking horizontal data from one sheet and summarizing it vertically in another sheet. The 1st sheet tallies student names vertically and corresponding data horizontally. The 2nd sheet will just be a temporary report showing just one student's data. I cannot figure this out and have studied many pages, including: https://stackoverflow.com/questions/60757377/excel-vba-read-cell-comment, https://stackoverflow.com/questions/66852586/reading-excel-cell-comments-gives-vba-error. Any help would be greatly appreciated.

DESIRED FUNCTIONALTY:

• Click in an even cell in col A to run a report of student data.
• Each student's data occupies 2 rows, the even row and the next odd row.
• Loop through each cell in the range of the 2 rows, placing the data in another temporary sheet.
• Student names are in column B.
• Student data starts in column E and expands columns to the right as needed.
• Many of the data cells contain threaded comments, and these comments need to be included but placed vertically into cells.

Please let me know if you need any additional info. The code is able to insert the new, temp worksheet and insert the headings (Number, Author, Date, Text), but no cell data and threaded comments data are being transferred over. Thank you.

Sub ListCommentsThreaded()
    Application.ScreenUpdating = False
    
    Dim wb As Workbook
    Dim myCmt As CommentThreaded
    Dim curwks As Worksheet
    Dim newwks As Worksheet
    Dim currng As Range
    Dim cell As Range
    Dim i As Long
    Dim cmtCount As Long
    
    Set wb = ThisWorkbook
    Set curwks = ActiveSheet
    
    'THE CURRENT RANGE WILL BE A SET OF TWO ROWS, STARTING IN COL B
    'THE RANGE LENGTH (# COLUMNS) WILL VARY PER STUDENT, ARBITRARILY SET AT 90 COLS
    'MANY OF THE CELLS IN THE RANGE WILL HAVE THREADED COMMENTS, STARTING IN COLUMN E
    'SOME CELLS MAY LACK COMMENTS
    
    'Set currng = curwks.Range(ActiveCell.Offset(0, 0), ActiveCell.Offset(1, 90))
    Set currng = curwks.Range(ActiveCell.Resize(1, 90).Address)
    
    Set newwks = wb.Worksheets.Add
    
    newwks.Range("B5:E5").Value = Array("Number", "Author", "Date", "Text")
          
    curwks.Activate
    i = 0
    For Each cell In currng.Cells
        If Not IsNumeric(cell.Value) Then
            With cell
                If Not .CommentThreaded Is Nothing Then
                    With newwks
                        i = i + 1
                        On Error Resume Next
                        .Cells(i, 1).Value = i - 1
                        .Cells(i, 2).Value = myCmt.Author.Name
                        .Cells(i, 3).Value = myCmt.Date
                        .Cells(i, 4).Value = myCmt.Text
                    End With
                End If
            End With
        End If
    Next cell
    
    With newwks
        .Columns(4).ColumnWidth = 50
        .Columns.AutoFit
        With .Cells
            .EntireRow.AutoFit
            .VerticalAlignment = xlTop
            .WrapText = True
        End With
    End With
    
    Application.ScreenUpdating = True
    
    End Sub

This works for me:

Sub ListCommentsThreaded()
    
    Application.ScreenUpdating = False
    
    Dim wb As Workbook
    
    Dim curwks As Worksheet, newwks As Worksheet
    Dim currng As Range, rw As Range, cell As Range
    Dim i As Long, cmtCount As Long, v
    
    Set curwks = ActiveSheet
    Set wb = ThisWorkbook
    
    Set currng = ActiveCell.Resize(2, 90)
    
    Set newwks = wb.Worksheets.Add
    Set rw = newwks.Range("B5:G5")
    rw.Value = Array("Number", "Address", "Cell Value", _
                     "Cmt. Author", "Cmt. Date", "Cmt. Text")
    
    i = 0
    For Each cell In currng.Cells
        v = cell.Value
        If Not IsNumeric(v) Then
            i = i + 1
            Set rw = rw.Offset(1)
            rw.Cells(1).Value = i
            rw.Cells(2).Value = cell.Address(False, False)
            rw.Cells(3).Value = v
            'does this cell have a comment?
            If Not cell.CommentThreaded Is Nothing Then
                With cell.CommentThreaded
                    rw.Cells(4).Value = .Author.Name
                    rw.Cells(5).Value = .Date
                    rw.Cells(6).Value = .Text
                End With
            End If 'has comment
        End If     'not numeric
    Next cell
    
    With newwks
        .Columns(4).ColumnWidth = 50
        .Columns.AutoFit
        With .Cells
            .EntireRow.AutoFit
            .VerticalAlignment = xlTop
            .WrapText = True
        End With
    End With
    
    Application.ScreenUpdating = True
    
End Sub