convert a wide column (containing multiple words/strings) to narrow one (just one word) in Excel using VBA

I have an Excel sheet with two columns: department and employees, like below:

In the second column I have multiple strings with a space delimiter.
I am trying to reformat this data into a narrow one that has one employee in the second column, and this is the VBA code that separates each word in the employees column but not with desired format:

Sub ExtractEmployee()

    Dim i As Long, j As Long
    Dim arr() As String
    Dim LastRow As Long
    
    LastRow = Cells(rows.count, "B").End(xlUp).row
    
    For i = 1 To LastRow
        arr = Split(Cells(i, 2), " ")
        For j = LBound(arr) To UBound(arr)
            Cells(i, 3 + j) = arr(j)
        Next j
    Next i
    
End Sub

The above code adds extra columns based on the number of strings in column B, which is not useful.
I need something like this:

Any help would be appreciated.

Splitting cells to new rows is easier with power query:

With the data selected, click on the ribbon Data > From Table / Range

After power query opens, Split Column > by Delimiter, Advanced options > Rows

Try this.

Sub ExtractEmployee2()

    Dim i As Long, j As Long
    Dim arr() As String
    Dim LastRow As Long
    Dim endRow As Long
    
    LastRow = Cells(Rows.Count, "B").End(xlUp).Row
' count total number of employees
    For i = 1 To LastRow
        arr = Split(Cells(i, 2), " ")
        endRow = endRow + (UBound(arr) - LBound(arr) + 1)
    Next i

' write cells, begining from last    
    For i = LastRow To 1 Step -1
        arr = Split(Cells(i, 2), " ")
        For j = LBound(arr) To UBound(arr)
            Cells(endRow, 1) = Cells(i, 1)
            Cells(endRow, 2) = arr(j)
            endRow = endRow - 1
        Next j
    Next i
    
End Sub