Use input from a ListBox in a different module

I want to integrate the user input from a ListBox into my macro.
The lead time would be 4 for example and if a user inputs a different value, this value should be taken instead.

For the Userfrom I have the following:

Public Lead_time As Double

Private Sub UserForm_Initialize()
   ListBox1.AddItem "1"
   ListBox1.AddItem "2"
   ListBox1.AddItem "3"
   ListBox1.AddItem "4"
   ListBox1.AddItem "5"
   ListBox1.AddItem "6"
   ListBox1.AddItem "7"
   ListBox1.AddItem "8"
   ListBox1.AddItem "9"
   ListBox1.AddItem "10"
End Sub
    
    
Private Sub Cmd_OK_Click()
   Dim Lead_time As Double
   Dim i As Integer
   For i = 0 To Me.ListBox1.ListCount
      If Me.ListBox1.Selected(i) = True Then
         Exit For
      End If
   Next i
   If i = Me.ListBox1.ListCount + 1 Then
      MsgBox "Select the numbers of lead time"
      Unload Days_lead_time
   End If
   Lead_time = Days_lead_time.ListBox1.value
   Unload Days_lead_time
End Sub

In my other module I load the UserForm but the input isn't being taken over sadly:

    Lead_time = 4
    Load Days_lead_time
    Days_lead_time.Show
    
    MsgBox CStr(Lead_time) 'here I was testing to see if the value was taken over from the UserFrom but it remains at 4. Even if I delete the standard 4 it doesn't show anything

This is the first time that I use UserFroms, so I'm a bit stuck sadly.

Update the code in your UserForm with this ... see the code comments for an explanation

Option Explicit

Public Lead_time As Double

Private Sub UserForm_Initialize()
    ' simpler setting of values into ListBox
    ListBox1.List = Array("1", "2", "3", "4", "5", "6", "7", "8", "9", "10")
End Sub

Private Sub Cmd_OK_Click()
    Dim i As Long
    For i = 0 To ListBox1.ListCount
        If ListBox1.Selected(i) Then
            ' get value (not index) of (first) selected item from ListBox
            Lead_time = CDbl(ListBox1.List(i))
            Exit For
        End If
    Next i
    If Lead_time = 0 Then
        MsgBox "Select the numbers of lead time"
    Else
        ' hide, but don't destroy, the UserForm to keep the 'Lead_time' variable alive
        Hide
    End If
End Sub

You can then use it like this

Dim Lead_time As Long
With New Days_lead_time
    .Show 
    ' because we have not Unloaded the UserForm, we can still access its members
    Lead_time = .Lead_time
End With
MsgBox Lead_time

... the key change is that the UserForm is not immediately unloaded and so the code that displayed it (the UserForm) can still get access to its members ... in this case, that is Lead_time that stores the selected value.