How to autorun a macro after opening a workbook?

I have managed to create a simple macro: When the cell B1 is active and an Enter key is pressed, the active cell is changed to the cell B4.

This is Module2:

Sub B1ToB4()
    Range("B4").Select
End Sub

This is Sheet1 under Microsoft Excel Objects:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If ActiveCell.Address = "$B$1" Then
        Application.OnKey "{ENTER}", "B1ToB4"
        Application.OnKey "~", "B1ToB4"
    Else
        Application.OnKey "{ENTER}"
        Application.OnKey "~"
    End If
End Sub

This is in ThisWorkbook, so that whenever I open the workbook, the cell B1 is selected.

Private Sub Workbook_Open()
    Range("B1").Select
End Sub

The problem I'd like to solve is that when I open the workbook and press Enter, the macro does not work and the active cell is changed to the B2, not B4. The problem may come from using the Worksheet_SelectionChange event which requires making some change in the worksheet in order to activate the macro. After doing some change, the macro starts to work. I'd like the macro to work right after opening the workbook without making any changes in it, so I'd appreciate some help. I've checked similar topics here, but I just don't know what to change in my case.

Insert this line in Workbook_Open

Private Sub Workbook_Open()
    Range("B1").Select
    set dummy = Range("B1")
    Sheet1.Worksheet_SelectionChange (dummy)
End Sub

and declare as Public Sub Worksheet_SelectionChange

This code in workbook module:

Option Explicit

Private Sub Workbook_Open()
   With Worksheets("SHEET01")
      .Activate
      .Range("B1").Select
   End With
End Sub

This code in a public module

Option Explicit

Public curCellAddress As String, enterEventIsSet As Boolean

Public Sub onEnter()
   If ActiveSheet.Name = "SHEET01" Then
      If curCellAddress = "B1" Then
         Cells(4, 2).Select
         Exit Sub
      End If
   End If
   Call removeENTEReventHandlers
End Sub

Public Sub setENTEReventHandlers()
   Application.OnKey "{ENTER}", "onEnter"
   Application.OnKey "~", "onEnter"
   enterEventIsSet = True
End Sub

Public Sub removeENTEReventHandlers()
   If enterEventIsSet Then
      Application.OnKey "{ENTER}"
      Application.OnKey "~"
      enterEventIsSet = False
   End If
End Sub

This code in the sheet's module.
In my example the sheet name is SHEET01

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   curCellAddress = Target(1).Address(0, 0)
   If curCellAddress = "B1" Then
      Call setENTEReventHandlers
   Else
      Call removeENTEReventHandlers
   End If
End Sub