Why is a further nesting of dynamic queries needed?

I am following this article: "I want to do X to all the Ys". But am confused by why it is necessary to convert an entire set of instructions to a string.

In particular, the article gives the following SQL code:

USE msdb;
GO
 
DECLARE @sql nvarchar(max) = space(0);
 
SELECT @sql += N'
EXEC sys.sp_refreshsqlmodule @name = N' + char(39) -- single quote
       + QUOTENAME(s.name) + char(46)              -- dot
       + QUOTENAME(v.name) + char(39) + char(59)   -- semi-colon 
  FROM sys.views AS v 
  INNER JOIN sys.schemas AS s
     ON v.[schema_id] = s.[schema_id];
 
PRINT @sql;
-- EXEC sys.sp_executesql @sql;

And notes that if the last line were uncommented then the code would execute to complete the intended task.

It then asks how to make this part of the query dynamic. But it is unclear to me why this part of the code needs to be made dynamic.

In the final script the article gives the original code as text string, but otherwise unchanged:

DECLARE @outerSQL nvarchar(max) = N'
    DECLARE @innerSQL nvarchar(max) = space(0);
 
    SELECT @innerSQL += N''
    EXEC sys.sp_refreshsqlmodule N'' + char(39)
         + QUOTENAME(s.name) + char(46)          
         + QUOTENAME(v.name) + char(39) + char(59)
    FROM sys.views AS v 
    INNER JOIN sys.schemas AS s
       ON v.[schema_id] = s.[schema_id];
 
    PRINT DB_NAME();
    PRINT @innerSQL;
    EXEC sys.sp_executesql @innerSQL;';
 
EXEC @exec @outerSQL;

I am struggling to understand why this change in the final code is necessary.

• The text generation in the final code appears static rather than dynamic
• The original code did not handle the choice of database, but the final code does not appear to handle this either.

What purpose does it serve to convert the original instructions to a string?

Looking back at the article following @Bart Hofland's comment I can see:

• Specifying the database to execute this code is done by constructing the string dbname.sys.sp_executesql and using this to execute the initial code.

• Hence, converting the original code to a text string allows it to be executed using this sp_executesql call.

So it is not that the initial code needs to be made more dynamic (though it could be), but that this allows the context to execute the code to be dynamic.