Why am I getting "Could not get unknown property 'BootRun' for root project" when I have the Spring boot gradle plugin installed

Trying to create a project that only uses h2 when running locally. Came up with this off of some answers...

plugins {
	id 'java'
	id 'war'
	id 'org.springframework.boot' version '3.1.1-SNAPSHOT'
	id 'io.spring.dependency-management' version '1.1.0'
}
...
configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
	localDatabase
}
...
dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-actuator'
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-data-rest'
	implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	localDatabase 'com.h2database:h2'
}
...
task bootRunLocal(type: BootRun, group: ApplicationPlugin.APPLICATION_GROUP, dependsOn: classes) {
	mainClass = 'com.cbusha.be.BackendApplication'
	classpath = sourceSets.main.runtimeClasspath + configurations.localDatabase
	systemProperty "spring.profiles.active", "local"
}

But when I run gradle bootRunLocal I get

A problem occurred evaluating root project 'backend'.
> Could not get unknown property 'BootRun' for root project 'backend' of type org.gradle.api.Project.

How do I get the custom task to work?

Import the class. Add:

import org.springframework.boot.gradle.tasks.run.BootRun

At the top of your buildscript.

Another answer that seemed to work but I replaced when I got the above answer was...

task bootRunLocal(type: JavaExec, group: 'Application') {
	classpath = sourceSets.main.runtimeClasspath + configurations.localDatabase
	mainClass = 'com.cbusha.be.BackendApplication' // Replace with the main class of your Spring Boot application
	args = ['--spring.profiles.active=local,test']
}