How to do a read with timeout on IO

How do I add a timeout for reading from an IO in julia?

function read_with_timeout(io::IO, timeout::Int)
    read(io, UInt16)
end

Is this a good impl?

function read_with_timeout(io::IO, type::Type, timeout::Int)
    sleepTime = 0.01
    totalTime = 0
    value = nothing
    @async value = read(io, type)
    while value === nothing
        if totalTime >= timeout
            throw(TimeoutException())
        end
        sleep(sleepTime)
        totalTime += sleepTime
    end
    value
end

The general idea of polling the task this way is definitely a valid solution. If you measure the actual time it takes for the timeout to trigger in your implementation you'll see that it takes longer thsn the requested timeout. It will always be slightly longer but we can be more accurrate by measuring the time that has passed instead of assuming that sleepTime had passed.

Your function is very similar to Base.timedwait which does the measuring a bit more carefully. Here is a version of the function with timedwait:

function read_with_timeout(io, type, timeout)
    task = @async read(io, type)
    status = timedwait(timeout) do
        istaskdone(task)
    end
    if status == :ok
        fetch(task)
    else
        throw(TimeoutException())
    end
end

There is a more serious issue with this function in both this implementation and your implementation. The started task is still around waiting for data and will silently consume any available data.

A nicer solution could probably be found by reaching for lower level reading functions but we can also interrupt the task (be mindful of race conditions):

function read_with_timeout(io, type, timeout)
    task = @async read(io, type)
    status = timedwait(timeout) do
        istaskdone(task)
    end
    if status == :ok
        fetch(task)
    else
        @async Base.throwto(task, TimeoutException())
        fetch(task)
    end
end