CMake: USES_TERMINAL argument in add_custom_command(TARGET) does not use console pool with Ninja

In CMake, if I use add_custom_command with USES_TERMINAL in order to get a prompt for a user's password when running a command using sudo, as seen in the following CMakeLists.txt snippet:

add_executable(my-app main.c)

add_custom_command(
    TARGET my-app
    POST_BUILD
    COMMAND sudo setcap cap_net_admin+eip $<TARGET_FILE:my-app>
    USES_TERMINAL
)

And then configure and build using Ninja:

$ cmake -G Ninja -B build
$ cmake --build build

The prompt for the user's password does not appear, and the build hangs. Looking at the resulting build.ninja file, I would expect there to be a pool = console setting for building my-app, but it's not present:

build my-app: C_EXECUTABLE_LINKER__my-app_ CMakeFiles/my-app.dir/main.c.o
  OBJECT_DIR = CMakeFiles/my-app.dir
  POST_BUILD = cd /home/bob/test_cmake_uses_terminal/build && sudo setcap cap_net_admin+eip /home/bob/test_cmake_uses_terminal/build/my-app
  PRE_LINK = :
  TARGET_COMPILE_PDB = CMakeFiles/my-app.dir/
  TARGET_FILE = my-app
  TARGET_PDB = my-app.pdb

If I manually add pool = console to that list, it properly prompts for the user's password when runnning the command.

I was able to get this to work in a more kludgey way using add_custom_target, but I'd like to know why USES_TERMINAL is not working as I interpret the documentation.

I'm using cmake version 3.24.1 and running on Ubuntu 22.04, if that helps.

Update:

Bug report submitted regarding this issue: https://gitlab.kitware.com/cmake/cmake/-/issues/25040

It turns out that USES_TERMINAL was never intended to be used when calling add_custom_command with TARGET in its signature.

The best way to have the terminal available to the custom command is to set the property JOB_POOL_LINK to console on the target on which the custom command is being added:

set_property(TARGET my-app PROPERTY JOB_POOL_LINK console)
add_custom_command(
    TARGET my-app
    POST_BUILD
    COMMAND sudo setcap cap_net_admin+eip $<TARGET_FILE:my-app>)

One other potential workaround would be to use add_custom_target with the USES_TERMINAL parameter, but this results in undesirable behavior of the command being executed on every build:

add_custom_target(
    run_sudo_setcap
    ALL
    COMMAND sudo setcap cap_net_admin+eip $<TARGET_FILE:my-app>
    DEPENDS my-app
    USES_TERMINAL)

Solution taken from the recommendation posted on the bug report related to this issue: https://gitlab.kitware.com/cmake/cmake/-/issues/25040#note_1381770

And note that the newest docs for CMake will no longer show USES_TERMINAL as a supported parameter to the add_custom_command(TARGET) command:

https://gitlab.kitware.com/cmake/cmake/-/merge_requests/8602

https://cmake.org/cmake/help/git-master/command/add_custom_command.html#build-events