Extracting Embedded Objects to save locally, Unable to get Object property of OLEObject class Error

I have a userform in excel 365 that can take file attachments. It embeds the selected files into a worksheet with the following code:

'puts file list entries into array
If DE_Form.AttachedFiles_List.ListCount > 0 Then
    For i = 0 To DE_Form.AttachedFiles_List.ListCount - 1
        ReDim Preserve FileNameArray(0 To i)
        FileNameArray(i) = DE_Form.AttachedFiles_List.List(i)
    Next i
End If

'adds icons for attached files to dc worksheet
For i = 0 To UBound(FileNameArray)
    'choose an icon based on filename extension
    'get all after last "." in filename
    FNExtension = Right(FileNameArray(i), Len(FileNameArray(i)) - _
                InStrRev(FileNameArray(i), "."))
 
    'select icon based on filename extension
    Select Case UCase(FNExtension)
    Case Is = "TXT"
      iconToUse = "C:\Windows\system32\packager.dll"

    Case Is = "XLS", "XLSM", "XLSX"
      iconToUse = "C:\Windows\Installer\{91140000-0011-0000-0000-0000000FF1CE}\xlicons.exe"

    Case Is = "PDF"
      iconToUse = "C:\Windows\Installer\{AC76BA86-1033-F400-7761-000000000004}\_PDFFile.ico"

    Case Else
      'this is a generic icon
      iconToUse = "C:\Windows\system32\packager.dll"
    End Select
    
    dc.Cells(GetLastRow(dc), 32 + i).ColumnWidth = 10
    dc.Cells(5, 32 + i).value = "Attached File " & i + 1
    dc.Cells(5, 32 + i).WrapText = True
    
    dc.Cells(GetLastRow(dc), 32 + i).value = FileNameArray(i)
    
    Set j = dc.OLEObjects.Add(fileName:=FileNameArray(i), _
                                link:=False, _
                                DisplayAsIcon:=True, _
                                IconFileName:=iconToUse, _
                                IconIndex:=0, _
                                IconLabel:=FileNameArray(i))
    On Error Resume Next
    
    With j
        '.ShapeRange.LockAspectRatio = msoFalse
        .Top = dc.Cells(GetLastRow(dc), 32 + i).Top
        .Left = dc.Cells(GetLastRow(dc), 32 + i).Left
        .Width = dc.Cells(GetLastRow(dc), 32 + i).Width
        .Height = dc.Cells(GetLastRow(dc), 32 + i).Height
    End With
    
Next i

I am trying to pull out the embedded files and save them to disk. I am also making an entry in an access database for each file. I can't save the files. I can open them (activate and I have also used the .verb xlprimary to open) but not save. I'd like to not use a bunch of SendKeys statements. I have tried using the indexes as references (this code does not), I'm activating the object first. I'm doing or have tried everything I can find on google. I keep getting an error. 'Unable to get the Object property of the OLEObject class'. I appreciate any help/advise. Thank you!

Dim NewCon As DAO.Database
Dim rs As DAO.Recordset2, rsattach As DAO.Recordset2
Dim fn() As String, fpath As String
Dim nfle As Object

'finds file objects and sets insert statement
For i = 6 To GetLastRow(ldc)
    For j = 32 To ldc.Cells(i, Columns.Count).End(xlToLeft).Column
        For Each k In ldc.OLEObjects
            k.Activate
                
            Select Case k.name
            Case Right(k.name, 6) = "Button", Right(k.name, 4) = "Icon":
            
            Case Else:
            
            If k.Left = ldc.Cells(i, j).Left Then
            
            Set NewCon = OpenDatabase("\\MyAccessDB.accdb")
            Set rs = NewCon.OpenRecordset("AttachedFiles", dbOpenTable)
            
            rs.AddNew
            
            rs.Fields("ProgramID") = ldc.Cells(i, "a").value
            fn = Split(ldc.Cells(i, j).Text, "\")
            rs.Fields("filename") = fn(UBound(fn))
            k.name = fn(UBound(fn))
            
            fpath = "\\MyFolderLocation\" & _
                k.name
            
            k.Object.SaveAs fpath                'Error is here
            
            rs.Fields("FileLocation") = fpath
            rs.Fields("Modified On") = ldc.Cells(i, "ae").value
            
            End If
            End Select
        Next k
    Next j
Next i

This is certainly not a full answer to the question, but far too long for a comment and I thought may help ... replace your line k.Object.SaveAs fpath with

Dim shp As Shape
Set shp = k.ShapeRange(1)
If shp.Type = msoEmbeddedOLEObject Then
    Debug.Print shp.OLEFormat.progID ' for info
    If shp.OLEFormat.progID Like "Excel*" Then
        shp.OLEFormat.Verb XlOLEVerb.xlVerbOpen
        Dim wkb As Workbook
        Set wkb = ActiveWorkbook
        wkb.SaveAs "C:\test\" & shp.Name & wkb.FileFormat ' change to your folder
        wkb.Close
    ElseIf shp.OLEFormat.progID Like "Acrobat*" Then
        ' do Acrobat stuff ... I don't have the Acrobat library
    ElseIf shp.OLEFormat.progID Like "Package*" Then
        shp.OLEFormat.Verb XlOLEVerb.xlVerbPrimary
        ' do Notepad stuff with SendKeys or Windows API?
    Else
        Debug.Print "Unknown ProgID '" & shp.OLEFormat.progID & "'"
    End If
Else
    Debug.Print shp.Name & " is not an embedded OLEObject"
End If

Needs code for Acrobat and Notepad, as per comments, but saves Excel files correctly. Definitely needs error handling!

Here's the final code I wound up with. Not totally finished but y'all get the idea. Thanks again @JohnM

'finds file objects and sets insert statement
For Each k In ldc.OLEObjects
     'saves file to sharedrive
    k.Activate
    Set shp = k.ShapeRange(1)
            
    If shp.Type = msoEmbeddedOLEObject Then
    
        'gets row and column of the object's address
        adrs = Split(shp.TopLeftCell.Address, "$")
        j = ldc.Range(adrs(1) & "1").Column
        i = adrs(2)
            
        Set NewCon = OpenDatabase("\\Server\Access.accdb")
        Set rs = NewCon.OpenRecordset("AttachedFiles", dbOpenTable)
            
        rs.AddNew
            
        rs.Fields("ID") = ldc.Cells(i, "a").value
        fn = Split(ldc.Cells(i, j).Text, "\")
        rs.Fields("filename") = fn(UBound(fn))
            
        fpath = "\\Server\MyFolder\"
            
        rs.Fields("FileLocation") = fpath
        rs.Fields("Modified On") = ldc.Cells(i, "ae").value
        
        'new path for object
        ldc.Cells(i, j).value = fpath & k.name
            
        'saves file to sharedrive
        
        Debug.Print shp.OLEFormat.progID ' for info
                
        Select Case True
                
        Case shp.OLEFormat.progID Like "Excel*":
            shp.OLEFormat.Verb XlOLEVerb.xlVerbOpen
                        
            Set wkb = GetObject("Worksheet in " & ThisWorkbook.name, "Excel.Application")
            wkb.SaveAs fileName:=fpath & shp.name
            wkb.Close
                    
        Case shp.OLEFormat.progID Like "Acrobat*":
            ChDir ("\\Server\Myfolder\")
                        
            shp.OLEFormat.Verb XlOLEVerb.xlVerbPrimary
            
            Set wrd = GetObject(, "AcroExch.App")
            
            'Send Keys method:
            wrd.Application.SendKeys "+^(s)", True 'Saves
            'Application.Wait Now + TimeValue("0:00:2")
                    
            wrd.Application.SendKeys shp.name, True 'Attempts to send new file name but doesn't.
            'Application.Wait Now + TimeValue("0:00:2")
                    
            wrd.Application.SendKeys "~", True
            'Application.Wait Now + TimeValue("0:00:2")
                    
            wrd.Application.SendKeys "^(q)", True 'closes the reader.
            'Application.Wait Now + TimeValue("0:00:2")
                
        Case shp.OLEFormat.progID Like "Word*", shp.OLEFormat.progID Like "textfile*":
            shp.OLEFormat.Verb XlOLEVerb.xlVerbOpen
                        
            Set wrd = GetObject(, "Word.Application")
                        
            Set wrdfle = wrd.Documents("Document in " & ThisWorkbook.name)
                        
            wrdfle.SaveAs fpath & shp.name
            wrd.Application.Quit
                    
        Case shp.OLEFormat.progID Like "PowerPoint*":
            shp.OLEFormat.Verb XlOLEVerb.xlVerbOpen
                        
            Set wrd = GetObject(, "PowerPoint.Application")
                    Set wrdfle = wrd.activepresentation
                        
            wrdfle.SaveAs fpath & shp.name
            wrdfle.Close
                
        Case shp.OLEFormat.progID Like "Package*":
            shp.OLEFormat.Verb XlOLEVerb.xlVerbPrimary
            ' do Notepad stuff with SendKeys or Windows API?
        Case Else:
            Debug.Print "Unknown ProgID '" & shp.OLEFormat.progID & "'"
        End Select
    NewCon.Close
    End If
Next k