Problem in stopping the operation in background worker

I want to run a number of logs with different text after every half second and stop after finishing. But I want it to stop when I click on the stop button and not show the rest of the logs.

Currently, when I click on the stop button, it stops after displaying the rest of the logs.

I put my code below.

Public WithEvents worker As New BackgroundWorker

Public Sub New()
    InitializeComponent()
    worker.WorkerSupportsCancellation = True
    worker.WorkerReportsProgress = True
End Sub

Private Sub start_Click(sender As Object, e As RoutedEventArgs) Handles start.Click
    If Not worker.IsBusy Then
        'check = False
        worker.RunWorkerAsync()
        start.Content = "STOP"
    Else
        worker.CancelAsync()
        start.Content = "Read Info"
    End If
End Sub

Public Sub XmlWrite(sender As Object, e As DoWorkEventArgs) Handles worker.DoWork
    While (Not worker.CancellationPending)
        If Not worker.CancellationPending Then
            Working()
            flash_log("Operation Completed ", MsgType.warning, True)
        Else
            Exit While
            Exit Sub
            log("Operation Canceled")
            worker.CancelAsync()
            Button.Content = "Read Info"
        End If
    End While
End Sub
   
End Sub

Private Sub Working()
    log("hello world  ")   '///// this is log Function
    log.Delay(0.5)
    log("I am Developer")
    log.Delay(0.5)
    log("My name Is shahab ")
    log.Delay(0.5)
    log("my Age Is 31")
    log.Delay(0.5)
    log("I love vb.net")
    log.Delay(0.5)
    If worker.IsBusy Then
        worker.CancelAsync()
    End If
End Sub

Your code is the sort of thing that you end up with when you try to write code without knowing what the code has to do first. You should ALWAYS work out the logic first, then write code to implement that specifically. Look at what your code actually does. It checks CancellationPending first, then it starts writing to the logs and it doesn't check CancellationPending again until it has written all the logs. If you don't check CancellationPending between writing, why would you expect it to exit?

The logic, in it's most form, is write the first log and then check whether cancellation is pending, then write the second log and then check whether cancellation is pending, etc, etc. What you probably ought to do in this very contrived case is to put all the messages in a list and then use a loop over that list. Inside the loop, you can write the next log and check whether a cancellation is pending.

Public Sub XmlWrite(sender As Object, e As DoWorkEventArgs) Handles worker.DoWork
    Dim logEntries = {
        "hello world  ",
        "I am Developer",
        "My name Is shahab ",
        "my Age Is 31",
        "I love vb.net"}

    For Each logEntry In logEntries
        If worker.CancellationPending Then
            e.Cancel = True

            Exit For
        End If

        log(logEntry)
        log.Delay(0.5)
    Next
End Sub

Private Sub worker_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles worker.RunWorkerCompleted
    If e.Cancelled Then
        Log("Operation Canceled")
    Else
        flash_log("Operation Completed ", MsgType.warning, True)
    End If

    start.Content = "Read Info"
End Sub

Note the proper use of the RunWorkerCompleted event as well.