My AutoHotkey script is showing as running but none of its intended task is happening

I need help with my AHK script

I wrote an AHK script that searches for windows with the title "Google Chrome," selects a random window from the list, activates it by bringing it to the foreground, and sets a random sleep time between 8 and 15 seconds before switching to another window of Google Chrome.

After executing the code, it seems it is running as it appeared on my tray section of my PC, but nothing actually happened, again, the intended task is to search for all Google Chrome windows opened and should randomly pick any of them and bring to the foreground to stay within 8 to 15 seconds, before switching to another Google Chrome window.

My AHK Script below:

#Persistent
SetTitleMatchMode, 2

Loop
{
	; Replace "App Name" with the common name of the application windows name
	WinGet, hWndList, List, Google Chrome

	if (ErrorLevel != "ERROR")
	{
		; Select a random window from the list
		Random, index, 1, % hWndList.MaxIndex()
		
		; Get the window handle of the selected window
		hWnd := hWndList%index%
		
		; Activate the selected window
		WinActivate, ahk_id %hWnd%
		
		; Define the time interval for switching windows (in milliseconds)
		Random, sleepTime, 8000, 15000 ; Adjust the values as needed
		Sleep, %sleepTime%
	}
	else
	{
		; No matching windows found, wait before checking again
		Sleep, 1000
	}
}

There is no such ErrorLevel as "ERROR" and WinGet^(docs) doesn't set an ErrorLevel anyway.

And since WinGet is a very legacy command, it returns a pseudo array. Because of that, you can't call .MaxIndex() on it. The number of elements in the pseudo array is specified in the output variable, as stated in the WinGet, , List documentation:

> Each ID number is stored in a variable whose name begins with OutputVar's own name (to form a pseudo-array), while OutputVar itself is set to the number of retrieved items (0 if none).

So your fixed code would be:

SetTitleMatchMode, 2

Loop
{
    ; Replace "App Name" with the common name of the application windows name
    WinGet, hWndList, List, Google Chrome

    if (hWndList != 0) ;can be replaced with just (!hWndList)
    {
        ; Select a random window from the list
        Random, index, 1, % hWndList

        ; Get the window handle of the selected window
        hWnd := hWndList%index%

        ; Activate the selected window
        WinActivate, % "ahk_id " hWnd

        ; Define the time interval for switching windows (in milliseconds)
        Random, sleepTime, 8000, 15000 ; Adjust the values as needed
        Sleep, % sleepTime
    }
    else
    {
        ; No matching windows found, wait before checking again
        Sleep, 1000
    }
}