Combine permutations with group limitation & lookup values that match these

I have a table like this

I want to make all Possible combinations of GROUP (but I want the LOAD Case Value)
but a group can't exist twice within the same combination
so for example I can't do
T + TL + W + Wx
but I can do T + TL + W or T + TL + Wx

after getting the combination I want to add the V, Hy, Hx, My, Mx Values of the combination
each in its corresponding column
so for T & Tl for column V it would be 3+8 = 11
I have a larger workbook with around possibly 900 combinations, and I did what u see below with hand, there's possibly some miscalculation but it's just to demonstrate what I need.
I also want the cell value to be dynamic so if I change any value in the V, Hy, Hx, My, Mx columns in the orange table, it will be reflected in the gray table

Wow, this was 2 questions in one really, but I figured it out:

part 1 was the possible combinations of single load case to a combination of load cases where the load cases listed in a similar group may not be combined with each other. This was the hardest part and I needed a few lambdas to get there:

Improved solution:

=LET(a,   A3:A6,
     b,   B3:B6,
     u,   TOROW(UNIQUE(a)),
     pa, REDUCE(TOCOL(u),SEQUENCE(COUNTA(u)-1,,COUNTA(u)-1,-1),
          LAMBDA(c,d,
                 VSTACK(c,
                        REDUCE(TOCOL(u),DROP(u,,d),
                        LAMBDA(e,f,
                               TOCOL(IFS(ISERR(FIND(u,e)),e&";"&u),3)))))),
     pas, SORT(DROP(REDUCE("",pa,LAMBDA(g,h,IFERROR(VSTACK(g,TEXTSPLIT(h,";")),""))),1)),
     pb,  DROP(REDUCE(0,SEQUENCE(ROWS(pas)),LAMBDA(x,y,VSTACK(x,REDUCE("",INDEX(pas,y,),LAMBDA(v,w,TOCOL(v&";"&TOROW(FILTER(b,a=w,"")),3)))))),1),
SUBSTITUTE(TRIM(SUBSTITUTE(pb,";"," "))," "," & "))

This version does not require another lambda at the end, which - if data increases (like in your sample file in the comments) - will completely freeze excel.

old version:

=LET(a,   A3:A6,
     b,   B3:B6,
     u,   TOROW(UNIQUE(a)),
     pa,  REDUCE(TOCOL(u),SEQUENCE(COUNTA(u)-1,,COUNTA(u)-1,-1),
          LAMBDA(c,d,
                 VSTACK(c,
                        REDUCE(TOCOL(u),DROP(u,,d),
                        LAMBDA(e,f,
                               TOCOL(IFS(ISERR(FIND(u,e)),e&";"&u),3)))))),
     pas, SORT(DROP(REDUCE("",pa,LAMBDA(g,h,IFERROR(VSTACK(g,TEXTSPLIT(h,";")),""))),1)),
     pb,  DROP(REDUCE(0,SEQUENCE(ROWS(pas)),LAMBDA(x,y,VSTACK(x,REDUCE("",INDEX(pas,y,),LAMBDA(v,w,TOCOL(v&";"&TOROW(FILTER(b,a=w,"")),3)))))),1),
BYROW(DROP(REDUCE("",pb,
           LAMBDA(x, y,
                  VSTACK(x,
                         TEXTSPLIT(y,";")))),1,1),
      LAMBDA(x,
TEXTJOIN(" & ",,x))))

Basically it first creates the possible permutations of single (unique) groups to the combination of these unique groups adding a different group one at a time.

Part 2 was the need to translate these group-permutations into it's load case-equivalent and if there's more equivalents, add these as another permutation as well.

Then to sum the V, Hy, Hx, My, Mx-values to the corresponding load cases in this spill range, I used the following:

=MAKEARRAY(ROWS(A8#),COLUMNS(D3:H6),
    LAMBDA(r,        c,
SUM(XLOOKUP(TEXTSPLIT(INDEX(A8#,r),," & "),
            B3:B6,
            INDEX(D3:H6,,c)))))