PowerQuery XML data import - combine nested table columns into one cell

I need the last 2 columns containing tables to be combined into a cell, currently the format of the import is:
title, link, description, pubDate, guid, toExpand
str, str, str, str, Table, Table

and I need
str, str, str, str, [str, str,..], [str, str, ..]

thanks in advance!

Query:

let
    Source = Xml.Tables(Web.Contents("https://patentscope.wipo.int/search/en/92ec30a9-24ed-4383-b1aa-7b76748f6266/rss.xml")),
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Attribute:version", Int64.Type}}),
    channel = #"Changed Type"{0}[channel],
    #"Changed Type1" = Table.TransformColumnTypes(channel,{{"title", type text}, {"link", type text}, {"description", type text}, {"language", type text}, {"pubDate", type datetime}, {"lastBuildDate", type datetime}}),
    item = #"Changed Type1"{0}[item],
    #"Changed Type2" = Table.TransformColumnTypes(item,{{"title", type text}, {"link", type text}, {"description", type text}, {"pubDate", type datetime}})
in
    #"Changed Type2"

I tried expanding the tables but that returns just each row as a table

Just expanding those tables won't work. You've got to "tease out" the relevant elements, and then combine them into a text string.

Perhaps something like this:

Note that I separated items with a semicolon ; but you might want to use a linefeed if you want the results to wrap in end result table

let
    Source = Xml.Tables(Web.Contents("https://patentscope.wipo.int/search/en/92ec30a9-24ed-4383-b1aa-7b76748f6266/rss.xml")),
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Attribute:version", Int64.Type}}),
    channel = #"Changed Type"{0}[channel],
    #"Changed Type1" = Table.TransformColumnTypes(channel,{{"title", type text}, {"link", type text}, {"description", type text}, {"language", type text}, {"pubDate", type datetime}, {"lastBuildDate", type datetime}}),
    item = #"Changed Type1"{0}[item],
    #"Changed Type2" = Table.TransformColumnTypes(item,{{"title", type text}, {"link", type text}, {"description", type text}, {"pubDate", type datetime}}),

//assuming only a single GUID in the "Table"
//If there might be more than one, need some code changes
    #"Expand GUID" = Table.TransformColumns(#"Changed Type2",{
        {"guid", each _[#"Element:Text"]{0}}}),
    
//Extract Creator
    Creator = Table.AddColumn(#"Expand GUID", "Creator", each let 
            #"Creator" = try Table.Column([#"http://purl.org/dc/elements/1.1/"],"creator"){0} otherwise null ,

        //expand if table
            #"Is Table" = Value.Is(#"Creator",type table),
            Result = if #"Is Table" then Text.Combine(#"Creator"[#"Element:Text"],"; ")
                        else #"Creator"
        in Result, type text),
    Contributor = Table.AddColumn(Creator, "Contributor", each let 
            #"Contributor" = try Table.Column([#"http://purl.org/dc/elements/1.1/"],"contributor"){0} otherwise null ,

        //expand if table
            #"Is Table" = Value.Is(#"Contributor",type table),
            Result = if #"Is Table" then Text.Combine(#"Contributor"[#"Element:Text"],"; ")
                        else #"Contributor"
        in Result),
    Identifier = Table.AddColumn(Contributor, "Identifier", each let 
            #"Identifier" = try Table.Column([#"http://purl.org/dc/elements/1.1/"],"identifier"){0} otherwise null ,

        //expand if table
            #"Is Table" = Value.Is(#"Identifier",type table),
            Result = if #"Is Table" then Text.Combine(#"Identifier"[#"Element:Text"],"; ")
                        else #"Identifier"
        in Result, type text),
    #"Removed Columns" = Table.RemoveColumns(Identifier,{"http://purl.org/dc/elements/1.1/"})
in
    #"Removed Columns"

Last Columns<br>