How to Insert function w/ dynamic value into every cell in column

I'm trying to paste and execute a function in every cell of column "F" over an unknown number rows.

The function is =QM_Stream_Delta(Value)

where Value is the cell contents of column "A" of the corresponding row.

Here's is my VBA script so far:

Sub GetDelta()
    FinalRow = Cells(Rows.Count, 1).End(xlUp).Row
    Dim i As Integer
    myFormula = "=QM_Stream_Delta(Value)"
    For i = 9 To FinalRow
        OptionSymbol = Cells(i, "A")
        Cells(i, "F").Value(myFormula(OptionSymbol)
    Next i
End Sub

I'm not sure how to actually get the function in there though -- I'm getting a syntax error for

Cells(i, "F").Value(myFormula(OptionSymbol)

Here is another use case for Formula2R1C1.

Sub GetDelta()
    Dim Target As Range
    
    Set Target = Range("F1").Resize(Cells(Rows.Count, 1).End(xlUp).Row)
    Set Target = Intersect(Target, Target.Offset(8))
    
    Target.Formula2R1C1 = "=@QM_Stream_Delta(RC1)"
End Sub

We should be in the habit of fully qualifying our references. Here I qualified the Target range to the Delta worksheet.

Sub GetDelta()
    Dim Target As Range
    
    With ThisWorkbook.Worksheets("Delta")
        Set Target = .Range("F1").Resize(.Cells(Rows.Count, 1).End(xlUp).Row)
        Set Target = Intersect(Target, Target.Offset(8))
    End With
    Target.Formula2R1C1 = "=@QM_Stream_Delta(RC1)"
End Sub

Use a reference to a cell within your formula.

Sub GetDelta()
    Const StartRow As Long = 9

    Dim FinalRow As Long
    FinalRow = Cells(Rows.Count, 1).End(xlUp).Row

    Range("F" & StartRow & ":F" & FinalRow).Formula = "=QM_Stream_Delta(A" & StartRow & ")"
End Sub

One issue i noticed is that you're starting your loop at row 9 rather than row 1. Your screenshot shows you want the inserted formulas to start at row 1.

I changed your macro to build the "function" you want, and then put it in the cell.

The function:

Sub GetDelta()
    FinalRow = Cells(Rows.Count, 1).End(xlUp).Row
    Dim i As Integer
    Dim myFormula As String
    For i = 1 To FinalRow
        myFormula = "=QM_Stream_Delta(A" & i & ")"
        Cells(i, "F").Formula = myFormula
    Next i
End Sub

I run it and it populates column F with the function. I don't know what the function QM_Stream_Delta() is, but the VBA macro places the formula in the cells:

So now you can run the VBA function, and automatically add the call to QM_Stream_Delta() in the rows you want, in the column you want:

Personally, I don't quite understand the virtue of this; Excel already has the ability to quickly populate a column of values. (<kbd>Ctrl</kbd>+<kbd>D</kbd>)