Terraform - reference specific resource that was created by 'count' by a value

In my Terraform code, I'm using a count to create multiple subnets in a vnet. This works great, but now, I want to reference the subnet ID in another resource. I can do this by using:

azurerm_subnet.subnets[1].id

but that's not very handy, something I would like to do is, instead of giving the index number, giving a name value it should match, something like this:

azurerm_subnet.subnets['where name = applicationsubnet'].id

Is there an option to do this?

Thanks!

> Is there an option to do this?

No, there is no such option. The closes you can get is by iteration. En example of a pseudo-code:

subnet_id = [for subnet in azurerm_subnet.subnets: subnet.id if subnet.name == "applicationsubnet"][0]

Otherwise, instead of count use for_each with keys based on name.

When you use count this suggests that all of the instances you are declaring are interchangable and thus it's unusual to then want to select an item by one of its attributes, because that suggests there's something special about that instance. That can be problematic because Terraform doesn't understand that there's something special about that instance and so if you change the count in future "the wrong instance" might get proposed for deletion.

For situations where there's some meaningful difference between your instances it's often better to use for_each and set the map keys to something that you'd want to look up the instances by. For example:

variable "subnets" {
  type = map(object({
    cidr_block = string
  }))
}

resource "azurerm_subnet" "example" {
  for_each = var.subnets

  address_space = [each.value.cidr_block]
}

If you were to set var.subnets like this...

{
  "applicationsubnet" = {
    cidr_block = "10.0.0.0/16"
  }
}

...then you would have an instance of the resource called aws_subnet.example["applicationsubnet"], and so you can look it up using that instance key.

Furthermore, if you for example change the cidr_block of one of the objects in this map later Terraform will use the map keys to understand which resource instance you were planning to change and thus plan to update that one only. If you remove an element from this map, the instance with the same key will be removed.

If your situation is unusual such that count is an appropriate thing to use here but yet you still need to look up by name anyway, you can use a for expression to derive a map from the list produced by count:

locals {
  subnets_by_name = tomap({
    for sn in azurerm_subnet.example : sn.name => sn
  })
}

You can then refer to local.subnets_by_name["applicationsubnet"] to look up the subnet object with that name.

However, Terraform will still track the instances of that resource with addresses like azurerm_subnet.example[0] and so you may need to take care with how you modify the original resource over time to make sure that the relationships between the instance keys like 0 and the names like "applicationsubnet" stay constant.