On error, show blank and resume to next row VBA MACRO

I have a very simple division for a range.

But on error, it should be: if cell D is empty, then E should also be empty.
I have tried lens and iferror or isblank and can't seem to get it to work.

Sub MyMacro()

Range("E9:E20").Formula = ("=1/D9")
    
End Sub

I didn't see the above comment but figured it out partially.
Search for a specific error to clear, and set that error to "".

Then I created a private macro to run the main macro every time there is a cell change, so blank cells can now have the formula added back in after initial error clear.

Note: you must put this into the specific sheet, or add in worksheet targets if you want this in a module.

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("P15:P134")) Is Nothing Then
Call MyMacro
End If
End Sub

Sub MyMacro()
    Dim Cell As Range
    
    Range("R15:R134").Formula = ("=1/P15")
    
            For Each Cell In Range("R15:R134")
                If IsError(Cell.Value) Then If Cell.Value = CVErr(xlErrDiv0) Then Cell.Value = ""
            Next Cell
End Sub

I guess the formula you are looking for is =IFERROR(1/D9,"")

This will execute and return the division, but if the result is any error (because D9 is empty or doesn't contain a number), it will return an empty string. Of course you can replace that with any value you want.

If you want to write that via VBA, it is often easier to change to R1C1-Notation: =IFERROR(1/RC[-1],"")

With ActiveSheet    ' Replace this when you want to work on a specific sheet
    Dim formula As String
    formula = "=IFERROR(1/RC[-1],"""")" 
    .Range("E9:E20").FormulaR1C1 = formula
End With

Update (after clarifying what is needed).
Have a look to the following code. You will for sure need to handle the user input using the Worksheet_Change-Event. The code has 2 pieces:

If something was entered in the first column, the cell to the right will get the formula - but only if it doesn't contain a fixed value.

If a value on the second column was removed, it will get the formula again. Just adapt the ranges in the two Intersect-commands to your needs.

Private Sub Worksheet_Change(ByVal Target As Range)

    Const formula = "=IFERROR(1/RC[-1],"""")"
    Application.EnableEvents = False
    On Error GoTo Change_Exit
    
    ' Handle first column
    Dim r As Range, cell As Range
    Set r = Intersect(Target, Range("D:D"))

    If Not r Is Nothing Then
        For Each cell In r
            Dim neighbor As Range
            Set neighbor = cell.Offset(0, 1)
            If neighbor.HasFormula Or IsEmpty(neighbor) Then
                Dim f As String
                neighbor.FormulaR1C1 = formula
            End If
        Next
    End If
    
    
    ' Handle second column
    Set r = Intersect(Target, Range("E:E"))
    If Not r Is Nothing Then
        For Each cell In r
            If IsEmpty(cell) Then    ' Value was deleted, write formula
                cell.FormulaR1C1 = formula
            End If
        Next
    End If
    
Change_Exit:
    Application.EnableEvents = True
End Sub