How do you store the namespace variable and its nested namespace children (its variable, etc) states in a file in TCL?

How do you save the namespace variable and its nested namespace children (its variable, etc) states in a file in TCL?

Storing the contents of the variables in a tree of namespaces is easy enough, as is storing the procedures in the namespaces. Storing the other commands that might be there and the variable traces... much harder! Plus the values in those variables might name ephemeral things like socket channels.

This does the simple thing, writing a generated Tcl script to an open channel; writing to a file is just a trivial wrapper around this.

proc storeNamespace {channel namespaceName} {
    # Set up the namespace and its variables
    set initBody {}
    foreach var [info vars $namespaceName::*] {
        # Tricky point; need to call [variable] in the NS before writing to vars there
        append initBody "\n" [list variable [namespace tail $var]]
    }
    puts $channel [list namespace eval $namespaceName $initBody]

    # Now we can actually write the contents of the variables out
    foreach var [info vars $namespaceName::*] {
        upvar 1 $var v
        # Two cases, arrays and simple variables
        if {[array exists v]} {
            puts $channel [list array set $var [array get v]]
        } else {
            puts $channel [list set $var $v]
        }
    }

    # Save the procedures too
    foreach p [info procs $namespaceName::*] {
        # Need to do extra work to handle arguments with defaults
        set args [lmap a [info args $p] {
            if {[info default $p $a def]} {
                list $a $def
            } else {
                list $a
            }
        }]
        # Write the procedure definition
        puts $channel [list proc $p $args [info body $p]]
    }

    # And recurse for the child namespaces
    foreach ns [namespace children $namespaceName] {
        storeNamespace $channel $ns
    }
}

# Example:
storeNamespace stdout ::foo