nextflow: use global variable and use .name in another script (create index)

I have two scripts: main.nf and index_process.nf Third I am creating without passing variable dummy_index_process.nf
I initially create index by passing parameters, however I understood that params. can be used under global scope.

When I pass variable I use .name on the fasta file. I'm unable to create index using global variable with .name at the step of output {.ann, .etc}

Please see below three code snippets: 1) main.nf 2) passing fasta to index 3) using global in index

main.nf

params.outdir_index_temp="./bwa_index_temp"
params.hg38genome ="/Users/username/Downloads/NM.fasta"

include {bwa_index} from './index_process.nf'
include {bwa_index_dummy} from './dummy_index_process.nf'

workflow {
	bwa_index(params.hg38genome)
	bwa_index_dummy()    
}

index_process.nf (works fine)

process bwa_index {

    tag {ref_fasta.name}

    publishDir "$params.outdir_index_temp/", mode:"copy"

    input:
    path ref_fasta

    output:
    tuple val(ref_fasta.name), path("${ref_fasta.name}.{ann,amb,sa,bwt,pac}")

    """
    bwa index "${ref_fasta}"
    """
}

dummy_index_process.nf (error with output path)

process bwa_index_dummy {

    tag {{params.hg38genome}.name}

    publishDir "$params.outdir_index_temp/", mode:"copy"

    output:
    tuple val(params.hg38genome), path("${{params.hg38genome}.name}.{ann,amb,sa,bwt,pac}")

    """
    bwa index "${params.hg38genome}"
    """
}

I am struggling at path("${{params.hg38genome}.name}.{ann,amb,sa,bwt,pac}") I cannot understand how to use .name

Error I get is:

ERROR ~ Error executing process > 'bwa_index (null)'

Caused by:
  Missing output file(s) `null.{ann,amb,sa,bwt,pac}` expected by process `bwa_index (null)`

Command executed:

  bwa index "/Users/name/Downloads/NM.fasta"

Command exit status:
  0

Command output:
  (empty)

Command error:
  [bwa_index] Pack FASTA... 0.01 sec
  [bwa_index] Construct BWT for the packed sequence...
  [bwa_index] 0.34 seconds elapse.
  [bwa_index] Update BWT... 0.01 sec
  [bwa_index] Pack forward-only FASTA... 0.01 sec
  [bwa_index] Construct SA from BWT and Occ... 0.11 sec
  [main] Version: 0.7.17-r1188
  [main] CMD: bwa index /Users/name/Downloads/NM.fasta
  [main] Real time: 0.494 sec; CPU: 0.491 sec

Work dir:
  /Users/name/Documents/path/nextflow_scripts/pipeline/work/c1/2916e08cb93e92d175520b9db71976

Tip: you can replicate the issue by changing to the process work dir and entering the command `bash .command.run`

 -- Check '.nextflow.log' file for details

This is because params.hg38genome is just a regular java.lang.String (i.e. a string). It has no
name attribute like file/path (sun.nio.fs.UnixPath) objects do. Without an input block, Nextflow will not know to stage any input files into the process working directory when the job is run. This will mean that there's no guarantee your FASTA file will be available when the job is run. On a shared/local filesystem, you may not notice any issues with an absolute path. But Nextflow pipelines are intended to be portable. If you later tried to run that code in the cloud for example, you'd likely get a FileNotFound exception or similar when your tool discovers that the file is missing. With regards to your first piece of code, you might also prefer:

process bwa_index {

    tag { ref_fasta.name }

    publishDir params.outdir_index_temp, mode:"copy"

    input:
    path ref_fasta

    output:
    tuple val(ref_fasta.name), path("*.{ann,amb,sa,bwt,pac}")

    """
    bwa index "${ref_fasta}"
    """
}