how to capture html input box text change event in vb.net

i need to populate a dropdown in vb.net on my html inputbox text change event.
Here is my input box.

<input ID="txtPositionDt"  runat="server" class="style247" name="txtPositionDt" 
                                                     size="10" tabindex="0" type="text" autocomplete="off" />

If you want this to occur automatically without the user having to press a button or do anything, then you could add some code to the web page (JavaScript), and this could/would/can be done.

However, in place of wiring up that custom code, you can get asp.net to do this all automatic for you, and without efforts.

Don't use an HTML input or control, but use one of the asp.net built-in controls. Those controls are not only a easy drag + drop into the webform, but they tend to work like desktop controls, and all of the "automatic" code behind is done automatic for you, and without efforts.

And, like a desktop dropdown/combo box, the web based ones also have provisions for 2 values (a hidden value, and a text value).

Let's try this with a asp.net dropdown.

Drag one on to the web form, setup using the property sheet, or use markup. (Again, it's really nice that you can just enter values in the property sheet, and then on the event tab).

We have this markup:

So really so far, this has been 100% drag and drop here.

So, we wind up with this:

<asp:DropDownList ID="DropDownList1" runat="server"
    AutoPostBack="true"
    OnSelectedIndexChanged="DropDownList1_SelectedIndexChanged"
    DataValueField="ID"
    DataTextField="HotelName"
    >
</asp:DropDownList>
<br />
<br />

<asp:TextBox ID="TextBox1" runat="server" TextMode="MultiLine" 
    Height="100px"
    width="260px"
    >
</asp:TextBox>

Ok, so now code behind:

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

    If Not IsPostBack Then

        LoadData

    End If

End Sub

Sub LoadData()
    ' all page setup and loading of data goes here
    DropDownList1.DataSource = MyRst("SELECT ID, HotelName FROM tblHotelsA 
                                      ORDER BY HotelName")

    DropDownList1.DataBind()
    DropDownList1.Items.Insert(0, "Select A Hotel")

End Sub

Protected Sub DropDownList1_SelectedIndexChanged(sender As Object, e As EventArgs)

    Dim sBuf As String =
        $"Drop down Text = {DropDownList1.SelectedItem.Text} {vbCrLf}" &
        $"Drop down (Hotel ID) value = {DropDownList1.SelectedItem.Value}"

    TextBox1.Text = sBuf

End Sub

And now we see/get this:

As you can see, this is not only easy, but then you not forced to add and write some JavaScript code in the client side browser. All of the moving parts are done automatic for you.

So, unless you have a really great reason to use a html control, as the above shows, use a asp.net control for this.

In above, for any general SQL query, then I created a helper routine that I use over and over in my general code. The function MyRst simple returns a data table.

So, for completeness, the routine MyRst (in a simple code module - thus global to all code) is this:

Public Function MyRst(strSQL As String) As DataTable

    Dim rstData As New DataTable
    Using conn As New SqlConnection(My.Settings.TEST4)
        Using cmdSQL As New SqlCommand(strSQL, conn)
            conn.Open()
            rstData.Load(cmdSQL.ExecuteReader)
            rstData.TableName = strSQL
        End Using
    End Using
    Return rstData
End Function

Edit: Just code to capture text box change.

Let's do the same with a text box.

So, we drop in a asp.net text box like this:

        <asp:TextBox ID="txtPositionDt" runat="server"
            AutoPostBack="true"
            OnTextChanged="txtPositionDt_TextChanged"
            autocomplete="off"
            >
        </asp:TextBox>
        <br />
        <asp:Label ID="Label1" runat="server" Text="">

        </asp:Label>

The code behind is this:

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load


End Sub


Protected Sub txtPositionDt_TextChanged(sender As Object, e As EventArgs)

    Label1.Text = "Value of text box = " & txtPositionDt.Text

End Sub

And the result is now this:

So, it is not really clear why you want a text box and also a drop down.

You either use a dropdownlist (a combo box), or as above shows you can have a regular asp.net textbox, and have a change event for what the user types into that text box.

So, you might be wanting a text box only, or maybe you want a dropdown (combo) box. It not 100% clear as to which you want here.

Last but not least?

Another possible goal here is to have a auto-search, or auto-complete as you type. When driven from a database, this is a "complex" task and goal, but there is a auto-complete as you type control from the ajaxtool-kit, and I do suggest that control be used if that is your goal.

In other words, a combo box (dropdownlist) should suffice in place of a text box, but as noted, it is possible you are looking for a database driven "search/complete" as you type, and if that is your goal, then I can post a working example.