Compounded Return In Kusto

if I have a table with a "Date" column and "Daily Return" column that specifies a stock's daily performance. How can I write a KQL query that would create Month to Date, year to date, and Total Cumulative returns? The right 3 columns are what I would be trying to replicate. For the sake of my example, MTD and YTD are the same, but in my actual datasets I obviously have several years worth of data with different months.

To find the cumulative daily return for nth day, formula is

Cumulative Daily Return of nth day = [(1 + Daily Return 1) * (1 + Daily Return 2) *..........*(1+ Daily Return n)]- 1

Example: To calculate the Cumulative return of 2nd day, applying the value in the above formula,
[(1+0.05)(1+0.02)]-1
=[1.051.02]-1
=1.071-1
=0.071

Since Kusto doesn't have any window function like row_cumsum() for cumulative product, we can sum the log10 values of daily return value using row_cumsum() function and then take the exp10 for the resultant value. Below is the code to calculate the total cumulative returns, cumulative returns for each month and same for each year.

Code:

let dailyReturns = datatable(Date:datetime, DailyReturn:real)
[
    datetime(2021-12-25), 0.05,
    datetime(2021-12-26), 0.02,
    datetime(2021-12-27), 0.03,
    datetime(2021-12-28), 0.02,
    datetime(2021-12-29), 0.01,
    datetime(2021-12-30), 0.03,
    datetime(2021-12-31), 0.04,
    datetime(2022-01-01), 0.02,
    datetime(2022-01-02), 0.02,
    datetime(2022-01-03), 0.05,
];
dailyReturns
| extend Month = getmonth(Date)
| extend Year = getyear(Date)
| order by Date asc 
| extend log_DR= log10(1+DailyReturn)
| extend month_cumsum_log_DR = row_cumsum(log_DR, Month != prev(Month))
| extend MTD_return=exp10(month_cumsum_log_DR)-1
| extend MTD_return = strcat(round(MTD_return * 100,2), "%")
| extend year_cumsum_log_DR = row_cumsum(log_DR, Year != prev(Year))
| extend YTD_return=exp10(year_cumsum_log_DR)-1
| extend YTD_return = strcat(round(YTD_return * 100,2), "%")
| extend total_cumsum_log_DR = row_cumsum(log_DR)
| extend Total_cumulative_return = exp10(total_cumsum_log_DR) - 1
| extend Total_cumulative_return = strcat(round(Total_cumulative_return * 100,2), "%")
| project Date,DailyReturn,MTD_return,YTD_return,Total_cumulative_return

Output:

Fiddle