Why does the and && operator in awk end up changing values in my input file?

Quick question, I am trying to check for certain patterns in my comma-delimited CSV files/data and I need the and operator &&. I choose to work with AWK.

Commands tried:

1:

cat file | awk -F "," 'BEGIN{ OFS=FS=","}
                       {if (($1="DIFF" && $2="DIFF" && $3="NODIFF"))
                          $(NF+1)="TRUE";
                        else $(NF+1)="FALSE";
                          print
                       }'  > outfile

2:

cat file | awk -F "," 'BEGIN{ OFS=FS=","}
                       {if (($1="DIFF" && $2="DIFF" && $3="NODIFF"))
                          $(NF+1)="TRUE";
                        else if (!($1="DIFF" && $2="DIFF" && $3="NODIFF"))
                           $(NF+1)="FALSE";print
                        }' > outfile

Input:

DIFF,DIFF,NODIFF
DIFF,NODIFF,DIFF
DIFF,DIFF,DIFF
NODIFF,DIFF,DIFF

Desired output:

DIFF,DIFF,NODIFF,TRUE
DIFF,NODIFF,DIFF,FALSE
DIFF,DIFF,DIFF,FALSE
NODIFF,DIFF,DIFF,FALSE

However, this is the output that I get and I don't know how to stop AWK from doing this??

1,1,NODIFF,TRUE
1,1,NODIFF,TRUE
1,1,NODIFF,TRUE
1,1,NODIFF,TRUE

I thought this was a simple way to do it but apparently I am missing something.

Thanks for any idea/suggestions,

$1="DIFF" is an assignment operation.

The comparison operator is ==; try $1=="DIFF", $2=="DIFF" and $3=="NODIFF"

As for how you generate a pair of 1's ...

• awk is having problems parsing the assignment which it thinks looks like $1=("DIFF" && $2="DIFF")
• an assignment is considered 'true' (aka 1) so $1=("DIFF" && $2="DIFF") becomes $1=("DIFF" && 1)
• a literal string, all by itself, is considered 'true' (aka 1) so $1=("DIFF" && 1) becomes $1=(1 && 1) which in turn becomes $1=1
• repeat for $2=("DIFF" && $3="NODIFF")
• obviously $3="NODIFF" is a more straightforward, simple assignment
• net result: all output lines start with 1,1,NODIFF

You do not need cat when you have file, GNU AWK can read on its own. You are attempting to set field separator both using -F and setting value of FS in BEGIN, strictly speaking this is not error, however this is redundant. You mixed = (assign) with == (equal check) which caused malfunction.

In this particular case you might get task done using just one regular expression following way, let file.txt content be

DIFF,DIFF,NODIFF
DIFF,NODIFF,DIFF
DIFF,DIFF,DIFF
NODIFF,DIFF,DIFF

then

awk 'BEGIN{FS=OFS=","}{$(NF+1)=/^DIFF,DIFF,NODIFF/?"TRUE":"FALSE";print}' file.txt

gives output

DIFF,DIFF,NODIFF,TRUE
DIFF,NODIFF,DIFF,FALSE
DIFF,DIFF,DIFF,FALSE
NODIFF,DIFF,DIFF,FALSE

Explanation: I inform GNU AWK that , is both field separator and output field separator, then I set next field to TRUE if line starts with (^) DIFF,DIFF,NODIFF else FALSE using so-called ternary operator condition?valueiftrue:valueiffalse and then print line.

(tested in GNU Awk 5.1.0)