How to specify rows for data to copy into for separate excel sheets

I would like the data from one excel sheet to copy over every other row into another separate sheet. For instance, the first line to be copied into would be cell B2 all the upto E2. The next line needs to be copied into B8 up to E8 and then after that from B14 to E14. How can I specify the data to copy into those specific rows and skip the others?

In VB I was able to get the data to copy over but cannot specify the exact cells.

Sub CopyData()
  ' Define the range of data that you want to copy
  Dim dataRange As Range
  Set dataRange = Range("A1:E1")

  ' Define the starting row and the interval at which you want to copy data
  Dim startRow As Integer
  Dim interval As Integer
  startRow = 2
  interval = 6

  ' Loop through each row
  For i = startRow To 1000
    ' Check if the current row is a row that you want to copy data into
    If i Mod interval = 0 Then
      ' Copy the data from the data range to the current row
      dataRange.Copy Cells(i, 2)
    End If
  Next i
End Sub

Copy a Single-Row Range Multiple Times With an Offset

<!-- language: lang-vb -->

Sub CopyRow()
    
    Const SRC_ROW As String = "A1:E1"
    Const DST_FIRST_CELL As String = "B2"
    Const DST_ROW_OFFSET As Long = 6
    Const DST_COPY_COUNT As Long = 3 ' 166
    
    Dim ws As Worksheet: Set ws = ActiveSheet ' improve!
    
    Dim srg As Range: Set srg = ws.Range(SRC_ROW)
    Dim dCell As Range: Set dCell = ws.Range(DST_FIRST_CELL)
    
    Dim n As Long
    
    For n = 1 To DST_COPY_COUNT
        srg.Copy dCell
        Set dCell = dCell.Offset(DST_ROW_OFFSET)
    Next n
  
End Sub

When you do a For...Next loop you can specify how much the variable will increment between loops. The default is 1, but if you want your loop to skip to the 6th next row, you can simply specify For i = a to b Step 6

Sub CopyData()
  ' Define the range of data that you want to copy
  Dim dataRange As Range
  Set dataRange = Range("A1:E1")

  ' Define the starting row and the interval at which you want to copy data
  Dim startRow As Integer
  Dim interval As Integer
  startRow = 2
  interval = 6

  ' Loop through each row
  For i = startRow To 1000 Step interval
      ' Copy the data from the data range to the current row
      dataRange.Copy Cells(i, 2)
  Next i
End Sub