Excel VBA: change date in cell when range in row is updated; laggy code

I am writing a code to change a date in column T when any cells in, column C to R are changed.

The code works but it's making the workbook super laggy and slow. Is there a way to make this code efficient?

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim WorkRng As Range, rrow As Long
    Dim Rng As Range
    Set WorkRng = Intersect(Range("B1:R300"), Target)
    If Not WorkRng Is Nothing Then
            For Each Rng In WorkRng
                rrow = Rng.Row
                If Not Rng.Value = "" Then
                    Cells(rrow, "T").Value = Now
                    Cells(rrow, "T").NumberFormat = "dd/mm/yyyy h:mm"
                Else
                    Cells(rrow, "T").ClearContents
                End If
            Next
    End If
End Sub

Try something like this if you want to clear the timestamp when a row has no data in columns B:R

Private Sub Worksheet_Change(ByVal Target As Range)
    Const FLAG_COL As String = "T"
    
    Dim WorkRng As Range, c As Range, rw As Range, cT As Range
    
    Set WorkRng = Intersect(Me.Range("B1:R300"), Target)
    If Not WorkRng Is Nothing Then
        For Each c In WorkRng.Cells
            Set rw = c.EntireRow
            Set cT = rw.Columns(FLAG_COL) 'timestamp cell
            'any data in B:R on this row?
            If Application.CountA(rw.Range("B1:R1")) > 0 Then
                cT.Value = Now
                cT.NumberFormat = "dd/mm/yyyy h:mm"
            Else
                cT.ClearContents
            End If
        Next
    End If
End Sub

The timestamp is updated on each row change in the selected Range and is deleted if all cells in the row have no value.

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim checkRange As Range, changedRange As Range, wrkRow As Range, rrow As Long
   Dim Rng As Range
   
   Err.Clear
   On Error GoTo Lerr
   Application.EnableEvents = False
   Set checkRange = Range("B1:R300")
   Set changedRange = Intersect(checkRange, Target)
   If Not changedRange Is Nothing Then
      For Each Rng In changedRange
         rrow = Rng.row
         If Rng.value = vbNullString Then
            Set wrkRow = Intersect(Rng.EntireRow, checkRange)
            If WorksheetFunction.CountA(wrkRow) = 0 Then
               Cells(rrow, "T").ClearContents
            Else
               GoTo LsetTimeStamp
            End If
         Else
LsetTimeStamp:
            Cells(rrow, "T").value = Now()
            Cells(rrow, "T").NumberFormat = "dd/mm/yyyy h:mm:ss"
         End If
      Next
   End If
Lerr:
   Application.EnableEvents = True
   If Err.Number <> 0 Then
      MsgBox ("Error> " & Err.Number & vbCrLf & Err.Description)
   End If
   On Error GoTo 0
End Sub