How can the output of my formula span across multiple cells?

In excel, I want to create a formula that has output a,b,c,d,e in cells Bx, Bx+1, Bx+2, Bx+3, Bx+4 respectively, if the cell value is duplicated 5 times (in this case '1' and '3' appear 5 times), and has output b,c,d,e in cells Bx, Bx+1, Bx+2, Bx+3 if the cell value is duplicated 4 times (in this case '2' appears 4 times).

In the below, column B is the output

How can I create this formula in Excel?

I suppose it'd be some variation of this formula:

=IF(COUNTIF(A:A,A1)=5, (paste values a,b,c,d,e in cells B1, B2, B3, B4, B5), (paste values b,c,d,e in cells B1, B2, B3, B4))

However I don't know how to fill in the value_if_true and value_if_false part of the above formula

=LET(a,TOCOL(A:A,1),
     b,MMULT(--(TOROW(a)=UNIQUE(a)),SEQUENCE(ROWS(a),,,0)),
DROP(
     REDUCE("", b,
     LAMBDA(x,  y,
     VSTACK(x,
            SORT(
                 INDEX({"e","d","c","b","a"},
                 SEQUENCE(y)))))),
     1))

This formula first stores a counter for each unique value in column A.
Then it creates an array of indexing e to a with a sequence of the counter (so if less than 5 are found, it will list the number of strings starting from e). This result is stacked to the previous result and iterates to the end.

Another take on this, using Frequency to get counts for each number and without using a lambda:

=LET(numbers,TOCOL(A:A,1),
 rows,COUNT(numbers),
 letters,"abcde",
 unique,UNIQUE(numbers),
 freq,DROP(FREQUENCY(numbers,unique),-1),
 indices,SEQUENCE(rows)-XMATCH(numbers,numbers)+1,
 MID(letters,indices+5-XLOOKUP(numbers,unique,freq),1)
)

CHAR(97) outputs "a;" subsequent letters can be output by incrementing upwards. Careful use of relative references can be a quick fix. Dragging =CHAR(96 + COUNTIFS(A$1:A1, A1)) down should adjust the range to only the cells above the row being calculated.

Otherwise, you ran use FILTER and ROW to create a more robust solution, although it will take longer to calculate due to the use of dynamic array formulas.

=CHAR(96 + COUNTA(FILTER(A:A, (A:A=A1) * (ROW(A:A) <= ROW()))))