Excel VBA: How to get a input from a user and highlight its positive and negative number from the range using VBA?

If I click a button it will show a inputbox and If the user writes 5 in inputbox then all the +5 and -5 should be highlighted from the column.

If anyone can help me with the VBA code of this it will be grateful. Thank you in advance.

It is good to know that you increase your chances to be helped if you prove that tried something by your own! A piece of code, even if it does not return what you need, some links to solution looking similar, but not solving the issue etc.

I am making an exception, hoping that you learned this aspect and next time will do what is to be done.

Please, try the next code and send some feedback after testing it:

Sub testHighlightInpNumbersInCol()

   Dim sh As Worksheet, lastR As Long, rngCol As Range, mtchCell As Range, searchNo As String
   Const colNo As Long = 1 'column number where the number to be searched
   
   Set sh = ActiveSheet
   lastR = sh.cells(sh.rows.count, colNo).End(xlUp).row 'last row on the searched column
   Set rngCol = sh.Range(sh.cells(1, colNo), sh.cells(lastR, colNo)) 'set the range keeping data
   rngCol.Interior.Color = xlNone                                    'remove any previous background colors
   
   searchNo = InputBox("Please, enter the numeric value to be highlighted", "Search for numbers") 'return the number to be searched
   
   If searchNo = "" Then MsgBox "You did not write anything...": Exit Sub   'in case of nothing input...
   If Not IsNumeric(searchNo) Then MsgBox "The input value MUST be numeric...": Exit Sub 'in case of alpha numeric entrance
   
   Set mtchCell = rngCol.Find(CDbl(searchNo), rngCol.cells(1), xlValues, xlWhole, xlByRows) 'find the cell with the positive value
   If mtchCell Is Nothing Then MsgBox searchNo & " could not be found...": Exit Sub 'if not found, exit
   mtchCell.Interior.Color = vbYellow                                                                                    'if found, color its interior in yellow
   
   Set mtchCell = rngCol.Find(-CDbl(searchNo), rngCol.cells(1), xlValues, xlWhole, xlByRows) 'find the negative value
   If mtchCell Is Nothing Then MsgBox "No negative value for " & searchNo & " could not be found...": Exit Sub
   mtchCell.Interior.Color = vbYellow
   
End Sub

The above code assumes that a single occurrence of the number (positive and negative) exists on the respective column. The code can be adapted to search for all occurrences, but it is also good to learn that we here are not mind reader and you need to clearly explain what you have and what you try accomplishing...