I am trying out XSLT 2.0 but I can't figure out an XPath related problem using following-sibling

This code below works but I want it to display the NEXT date that the charts will be available.
My output is:
Today is: 06/08/2023
Current Cycle Date: 05/18/2023

Time for new charts.

I'm trying to get it to have another message line showing the date that the next charts will be available so it would produce an output like this:

Today is: 06/08/2023
Current Cycle Date: 05/18/2023
Next new charts: 06/15/2023
Time for new charts.

I have a commented line that would use $dtSchedNext as the variable that would be the next date but I cannot come up with a way to populate this variable with that date. I think I should use following-sibling but my XPath is not too good and I have been stuck for too long and would appreciate any help.

My command line is:
java -jar "C:\Program Files\Saxonica\SaxonJ HE 12.1\saxon-he-12.1.jar" -s:Schedule.xml -Thiscodebelow.xsl

The XML is:
Schedule.xml

  <schedule>
    <cycle>
      <date>2023-05-18-05:00</date>
      <yc>2305</yc>
      <enr>n</enr>
    </cycle>
    <cycle>
      <date>2023-06-15-05:00</date>
      <yc>2306</yc>
      <enr>y</enr>
    </cycle>
    <cycle>
      <date>2023-07-13-05:00</date>
      <yc>2307</yc>
      <enr>n</enr>
    </cycle>
    <cycle>
      <date>2023-08-10-05:00</date>
      <yc>2308</yc>
      <enr>y</enr>
    </cycle>
  </schedule>

Here is my working stylesheet though it doesn't output the needed date.

`<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                version="2.0">
  <xsl:output method="text"/>
  <xsl:variable name="docSchedule" select="document('Schedule.xml')/schedule"/>
  <!-- Returns today's date formatted as '2023-02-05-05:00'  -->
  <xsl:variable name="dtToday" as="xs:date" select="xs:date(current-date())"/>
  <!-- Opens schedule.xml,sets context to children of the root 'schedule' -->
  <!--  and returns the latest 'cycle' node only -->
  <xsl:variable name="schedCycles" select="$docSchedule/*[date < $dtToday]"/>
  <xsl:variable name="cycleLast" select="$schedCycles[position()=last()]"/>
  <!-- Extract the value of 'date' from the current cycle node -->
  <xsl:variable name="dtSched" as="xs:date" select="$cycleLast/date"/>
  <xsl:template match="/">
    <xsl:message terminate="no">Today is:
      <xsl:value-of select="format-date($dtToday,'[M01]/[D01]/[Y1]')"/>Current Cycle Date:
      <xsl:value-of select="format-date($dtSched,'[M01]/[D01]/[Y1]')"/>
      <!--  Next new charts`your text`:    <xsl:value-of select="format-date($dtSchedNext,'[M01]/[D01]/[Y1]')"/> -->
    </xsl:message>
    <xsl:choose>
      <xsl:when test="$dtToday gt $dtSched">
        <xsl:message terminate="no">
       Time for new charts.
        </xsl:message>
      </xsl:when>
      <xsl:when test="$dtToday lt $dtSched">
        <xsl:message terminate="no">
       Charts Are up to date.
        </xsl:message>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>`

$cycleLast/following-sibling::cycle[1] gives you the next cycle element following the one you selected in $cycleLast.

Below is what I finally ended up with. I had to extract the date data from the string that was returned by Marten's suggestion and then cast that as an xs:date so I could format it with format-date(). I hope this helps anybody else in the future as this was quite the exercise in XSLT2.0's date handling capabilities.

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                version="2.0">
  <xsl:output method="text"/> 
  <xsl:variable name="docSchedule" select="document('Schedule.xml')/schedule"/>
  <!-- Returns today's date formatted as '2023-02-05-05:00'  -->
  <xsl:variable name="dtToday" as="xs:date" select="xs:date(current-date())"/>
  <!-- Opens schedule.xml,sets context to children of the root 'schedule' -->
  <!--  and returns the latest 'cycle' node only -->
  <xsl:variable name="schedCycles" select="$docSchedule/*[date < $dtToday]"/>
  <xsl:variable name="cycleLast" select="$schedCycles[position()=last()]"/>
  <!-- Extract the value of 'date' from the current cycle node -->
  <xsl:variable name="dtSched" as="xs:date" select="$cycleLast/date"/>
  <xsl:variable name="cycleNext" select="substring($cycleLast/following-sibling::cycle[1],1,10)"/>
  <xsl:variable name="dtNext" select="xs:date($cycleNext)"/>
  <xsl:template match="/">
    <xsl:message terminate="no">
      Today is:              <xsl:value-of select="format-date($dtToday,'[M01]/[D01]/[Y1]')"/>
      Current Cycle Date:    <xsl:value-of select="format-date($dtSched,'[M01]/[D01]/[Y1]')"/>
      Next new charts:       <xsl:value-of select="format-date($dtNext,'[M01]/[D01]/[Y1]')"/>
    </xsl:message>
    <xsl:choose>
      <xsl:when test="$dtToday gt $dtSched">
        <xsl:message terminate="no">
       Time for new charts.
        </xsl:message>
      </xsl:when>
      <xsl:when test="$dtToday lt $dtSched">
        <xsl:message terminate="no">
       Charts Are up to date.
        </xsl:message>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

Just use:

(/*/cycle/date[xs:date(.) gt current-date()])[1]/string()

XSLT 2.0 - based verification:

This transformation:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:variable name="dtToday" as="xs:date" select="xs:date(current-date())"/>

  <xsl:template match="/*">
    <xsl:sequence select=
    "(/*/cycle/date[xs:date(.) gt current-date()])[1]/string()"/>
  </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<schedule>
	<cycle>
		<date>2023-05-18-05:00</date>
		<yc>2305</yc>
		<enr>n</enr>
	</cycle>
	<cycle>
		<date>2023-06-15-05:00</date>
		<yc>2306</yc>
		<enr>y</enr>
	</cycle>
	<cycle>
		<date>2023-07-13-05:00</date>
		<yc>2307</yc>
		<enr>n</enr>
	</cycle>
	<cycle>
		<date>2023-08-10-05:00</date>
		<yc>2308</yc>
		<enr>y</enr>
	</cycle>
</schedule>

Evaluates the XPath expression and outputs the correct, expected result (note that today is 6/18/2023, thus the correct result will not be the one initially stated in this problem):

2023-07-13-05:00