VB.Net How to pass pass different objects into sub

How do you setup this sub so that you can pass different objects into it?

Protected Shared Sub exampleSub(Optional ByRef partDescription as DoorDescription = Nothing)
    For Each feat In partDescription.MirrorFeatures
        ...
    Next
End Sub

Public Class DoorDescription
    Public Property MirrorFeatures As New List(Of Feature)
End Class

Public Class WindowDescription
    Public Property MirrorFeatures As New List(Of Feature)
End Class

exampleSub(DoorDescription)

exampleSub(WindowDescription)

Looking to setup this sub so that it will work with DoorDescription and WindowDescription.

Make an abstract class from which both the WindowDescription and DoorDescription inherit

Public MustInherit Class EntrywayDescription
    Public Property MirrorFeatures As List(Of Feature)
End Class

Similarly, an Interface would work

Public Interface IEntrywayDescription
    Property MirrorFeatures As IEnumerable(Of Feature)
End Interface

Then your classes would Inherit (or Implement in the case of the Interface) the base class or Interface

' abstract class
Public Class DoorDescription
    Inherits EntrywayDescription
End Class
' interface
Public Class WindowDescription
    Implements IEntrywayDescription
End Class

You can use it like this. If you have more common functionality between both classes, you can add it to the base class and access when the reference is of the base class type

Public Sub example(partDescription As EntrywayDescription)
    For Each feat In partDescription.MirrorFeatures

    Next
End Sub

Typically you may want to use the base class inheritance method if you have shared concrete functionality between the two classes. For example,

Public MustInherit Class EntrywayDescription
    Public Property MirrorFeatures As List(Of Feature)
    Public ReadOnly Property GetFeaturesString As String
        Get
            Return String.Join(", ", MirrorFeatures.Select(Function(f) f.ToString()))
        End Get
    End Property
End Class

Use the Interface otherwise, but you will then need to implement the interface members individually in each class which implements it, for example

Public Class DoorDescription
    Implements IEntrywayDescription

    Private _mirrorFeatures As List(Of Feature)
    Public Property MirrorFeatures As IEnumerable(Of Feature) Implements IEntrywayDescription.MirrorFeatures
        Get
            Return _mirrorFeatures
        End Get
        Set(value As IEnumerable(Of Feature))
            _mirrorFeatures = value.ToList()
        End Set
    End Property
End Class