File::Find::Rule - duplicated output

My subroutine parses my hashes correctly and returns (basically) correct.

The problem is I get the return twice.
It is the twice part that I do not understand.

Sample data:

$local_h{$local}{name} = "somefile.txt";
$local_h{$local}{size} = 12345;

sub already_here {
    foreach my $local (keys(%local_h)) {
        my $tmp = $local_h{$local}{name};
        my $FFR_rule = File::Find::Rule
            ->size($local_h{$local}{size})
            ->start( @volumes );
        while ( defined ( my $match = $FFR_rule->match ) ) {
            my ( $name, $path, $suffix ) = fileparse($match);
            if ( $name =~ /$local_h{$local}{name}/ ) {
say "\t$name $name has been matched by size and name to:\n\t $path$name\n";
#   Matches can occur multiple times, to be dealt with later/elsewhere
            } else {

say "$match  Matched by size only\n";
#   Maybe this really is the location but got renamed locally.
#   For now I will consider it an edge-case.
            }
        }
    }
}

output:

somefile.txt has been matched by size and name to: a/path/to/somefile.txt
somefile.txt has been matched by size and name to: some/other/path/to/somefile.txt 

34thx.foo   Matched by size only

somefile.txt has been matched by size and name to: a/path/to/somefile.txt
somefile.txt has been matched by size and name to: some/other/path/to/somefile.txt 

34thx.foo   Matched by size only

I am expecting to see 3 lines of output (4 if you count the blank line).
I am completely failing to see the source of the duplication.

There are two possibilities. There are two entries in %local_h with the same name and size, or you scan the same directory twice. You could scan the same directory twice if two entries in @volumes are it or an ancestor.

That said, the approach you are taking is awful.

Let's say there are 10 files in %local_h and 10 files on disk. You will be traversing the tree 10 times. Which means you will check the 10 files 10 times each, for a total of 100 calls to stat! For 20 and 20, that's 400 calls! There's no reason to do that. In each of those scenarios, the following only does 20 (instead of 100) and 40 (instead of 400) calls to stat respectively:

my %interesting;
for ( values( %local_h ) ) {
   ++$interesting{ $_->{ size } }{ $_->{ name } };
}

my $ffr = File::Find::Rule->start( @volumes );
while ( defined( my $qfn = $ffr->match ) ) {
   my $fn = basename( $qfn );
   my $size = -s $qfn;

  if ( my $r = $interesting{ $size } ) {
      if ( $r->{ $fn } ) {
         say "$fn size+name $qfn";
      } else {
         say "$fn size $qfn";
      }
   }
}