In Word VBA, why does the InlineShape object's Delete method not work reliably?

A problem that I've run across a few times over the years is that, when developing code that deletes InlineShape objects from a Word document's InlineShapes collection, while in the VBE window testing code that calls each InlineShape object's Delete method, those calls don’t delete the object, they instead delete the document's currently selected text or, if the selection is collapsed, they delete the character to the right of the insertion point.

If I single-step through the code, it deletes none of the InlinShapes and, instead, deletes text. If I run the entire deletion-loop (from within the VBE window), it will delete some of the objects but then delete the insertion-point text instead of the last object to be deleted. But, usually (under some document-content circumstances), when the document is the active window (not the VBE window) and the code is executed by way of a user interaction (such as run from the Macros menu) then it executes correctly, deleting all InlineShape objects and leaving all text intact. However, in other document-content circumstances, it sometimes leaves one of the InlineShape objects intact. (I have yet to determine the particular circumstances that result in the last case.)

For reference, here's some code that demonstrates the problem.

Setup:

1. Open a new document.

2. Add the text "This is a test" to the document.

3. Below that, add three ActiveX CommandButton objects to the document.

4. Double-click the word "This" in the document's text, which will select it and its trailing space character.

5. Save the document

6. In File Explorer, right-click the document file, select Properties, and set it to Read-only (to prevent accidentally overwriting its original state).

7. Open the VBE window and, in a standard module, add the following code:

   Sub Demo()
       Dim i As Integer
   
       With ThisDocument
           Debug.Print "Before:"
           For i = .InlineShapes.Count To 1 Step -1
               Debug.Print "    " & .InlineShapes(i).OLEFormat.Object.Name 'To the Immediate window
           Next i
   
           For i = .InlineShapes.Count To 1 Step -1
               Debug.Print "Deleting " & .InlineShapes(i).OLEFormat.Object.Name
               .InlineShapes(i).Delete
           Next i
   
           Debug.Print "After:"
           For i = .InlineShapes.Count To 1 Step -1
               Debug.Print "    " & .InlineShapes(i).OLEFormat.Object.Name
           Next i
       End With
   End Sub
   

Test-1: In the VBE window, single-step through the demo code. My result is that no InlineShape objects (the ActiveX controls) actually get deleted and, instead, the word "This" and its trailing space character get deleted by the first call to the InlineShape object's Delete method, and the following "i" and "s" characters get deleted by the second and third Delete method calls. (Also note the trace information printed to the Immediate window.)

Test-2: Close the document without saving it, then re-open it and double-click the word "This" again. In the VBE window, run the Demo routine straight through without single-stepping. My result is that the first two InlineShape objects get deleted but the word "This" and its trailing space character get deleted instead of the third object, which remains.

Test-3: Close the document without saving it, then re-open it and double-click the word "This" again. Without opening VBE, in the Word ribbon’s View tab, select Macros=>View Macros. Run the Demo routine from there. My result is that all three InlineShape objects get correctly deleted and the word "This" remains intact, correctly. However, in production code, I have seen cases where no InlineShape objects are deleted or all but one are deleted when run in the normal manner. I have no clue what circumstances produce those varying results.

Obviously this is a bug, but does anyone know whether there is some obvious technique that results in reliable execution of the InlineShapes Delete method under all circumstances?

In any case, historically, I’ve resorted to the following workaround that works when run normally and also works while single-stepping through the code, which I provide here in case anyone else finds it useful.

There are three workarounds (known to me):

1. First convert each ActiveX InlineShape object to a Shape object (by calling its ConvertToShape method) and then delete them via the Shapes collection. This workaround is not preferred because of the extra complexity and overhead of the second collection-traverse loop. (Note that the Shapes loop must check for a Shape.Type property of msoOLEControlObject instead of wdInlineShapeOLEControlObject).

2. Select the InlineShape object's range and delete it via the Selection object's Delete method. This workaround is not preferred due to the extra overhead of saving the current selection, selecting each InlineShape for deletion, then restoring the original selection when done.

3. Simply replace the InLineShape object's range content with a null string. Doing so automatically deletes the object from the InlineShapes collection. This workaround is preferred due to its simplicity.

Code:

Sub DeleteAllActiveXControls(wdDoc As Word.Document)
    '
    'Deletes all ActiveX controls in the specified document.
    '
    '*************************************************************************************************************

    Dim i As Integer

    '*************************************************************************************************************
    'Word InLineShape Delete method BUG WORKAROUND --- WORKAROUND --- WORKAROUND --- WORKAROUND --- WORKAROUND
    '
    'Word has a bizarre bug in which a call to an InLineShape object's Delete method doesn't reliably delete the
    'shape.  Testing has demonstrated that the problem always manifests while single-stepping through the deletion
    'code.  When the code is executed normally by way of some user interaction with the document, some of the
    'InLineShape objects do get deleted, but not all of them get reliably deleted (under circumstances that I have
    'yet to determine).
    '
    'This is clearly a bug because the Delete method does not *reliably* function as advertised by Microsoft's
    'reference documentation: https://learn.microsoft.com/en-us/office/vba/api/word.inlineshape.delete
    '
    'The simplest workaround that I've found is to just replace the InLineShape object's range content with a null
    'string.
    '
    With wdDoc
    For i = .InlineShapes.Count To 1 Step -1
        If .InlineShapes(i).Type = wdInlineShapeOLEControlObject Then '(ActiveX control)
            .InlineShapes(i).Range = "" 'Delete the InlineShape object's current range content by replacement,
        End If                          'which automatically deletes the object from the InlineShapes collection.
    Next i
    End With
    '
    'END WORKAROUND --- END WORKAROUND --- END WORKAROUND --- END WORKAROUND --- END WORKAROUND --- END WORKAROUND
    '*************************************************************************************************************
End Sub