How to correctly define multiple sets of values as config values in snakemake

I have a snakefile that is looping through a set of isolates to run 2 python scripts. I want to set a set of values as the script flags but I do not know how to do it without a bash script.

import os
grouphome = os.environ['GROUPHOME']
ISOLATES = [i for i in open(grouphome+'/isolates.txt').read().split('\n') if len(i) > 0]
window_size=config["window_size"]
slide_size=config["slide_size"]
mean_filter_size =config["mean_filter_size"]
rule all:
    input:
        expand(grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/{isolate}.csv", isolate=ISOLATES,window_size=config["window_size"],slide_size=config["slide_size"],mean_filter_size=config["mean_filter_size"]),
	    expand(grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/ptr/{isolate}/ptr.csv", isolate=ISOLATES,window_size=config["window_size"],slide_size=config["slide_size"],mean_filter_size=config["mean_filter_size"]),
	    expand(grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/ptr/{isolate}/residuals_fitted_values.csv",isolate=ISOLATES,window_size=config["window_size"],slide_size=config["slide_size"],mean_filter_size=config["mean_filter_size"])
rule coverage_preprocessing:
    input:
        input1= grouphome+"/data/{isolate}.fasta",
        input2= grouphome+"/max_coverage/{isolate}_maximum_coverage.csv"
    params:
        window_size=config["window_size"],
        slide_size=config["slide_size"],
        mean_filter_size =config["mean_filter_size"]
    output: grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/{isolate}.csv"
    shell:
        """./preprocess_coverage.py -i {input.input2} -g {input.input1} -sw {params.slide_size} -ws {params.window_size} -m mean -bm mean -bs {params.mean_filter_size} -o {output}"""
rule calc_bptr:
    params:
        window_size=config["window_size"],
        slide_size=config["slide_size"],
        mean_filter_size =config["mean_filter_size"]
    input:
        input1= grouphome+"/data/{isolate}.fasta",
	    input2= grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/{isolate}.csv"
    output:
        output1= grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/ptr/{isolate}/ptr.csv",
        output2= grouphome+"/preprocessed_coverage_{window_size}_{slide_size}_{mean_filter_size}/ptr/{isolate}/residuals_fitted_values.csv",
    shell:
        """./calculate_bptr.py -i {input.input2} -b mean -s {params.mean_filter_size} -g {input.input1} -f {output.output2} -o {output.output1}"""

I am using the following command to run it
snakemake --config window_size=1000000 slide_size=10000 mean_filter_size=99 --cores=9

How do I set multiple sets of values for --config?
e.g., 1000000,10000,99
1000000,100,66 or etc.

There are multiple layers of the problem.

First, I would prefer passing configfile to snakemake call, e.g.: snakemake --config config.yaml with the config.yaml containing values for parameters. There, you can specify a list of values for the parameter, such as:

window_size:
  - 1000
  - 2000

slide_size:
  - 5
  - 10

The second problem is how to run a rule with a list of parameter values.
I would suggest specifying outputs for all parameter values in the all, with the downstream rules taking parameter values from wildcards.

# this rule requests all combinations of these two parameters, that you passed as a list from the config.
rule all:
    input:
        expand(
            "results/{window_size}_{slide_size}.csv",
            window_size=config["window_size"],
            slide_size=config["slide_size"]
        ),

# this rule parses from the output parameter values, this is accessed using wildcards object
rule preprocess_coverage:
    input:
        ...,
    output: 
        "results/{window_size}_{slide_size}.csv"
    shell:
        "... -sw {wildcards.slide_size} -ws {wildcards.window_size} -o {output}"

Using the example config.yaml from above, the first rule - all rule - requests the following files: results/1000_5.csv, results/1000_10.csv, results/2000_5.csv and results/2000_10.csv. Snakemake recognize that the rule preprocess_coverage can produce these files by setting the wildcards values, that are then accessed in the shell directive of the rule as parameters for the script.

See more about wildcards here, and about expand function here.

In expand function you can provide any combinatorial function to produce the results, i.e. to produce only results/1000_5.csv and results/2000_10.csv use the zip function:

rule all:
    input:
        expand(
            "results/{window_size}_{slide_size}.csv",
            zip,
            window_size=config["window_size"],
            slide_size=config["slide_size"]
        ),

With Snakemake 5.31 and above, there is also another option: parameter space exploration, there is a well-written description in the Snakemake manual. ParamSpace simplifies the above approach, but it works the same with less code. I would recommend to try the above first, as it is important to understand the above to understand how ParamSpace works.