Saving multiple graphs as images through vba

Good morning,

I have an excel file that has multiple graphs

each graph is named graph_i where i is a number from 1 to 100

I would like to write a vba code that enable me to save these graphs as images.

The title of the image must be identical to the tile of the graph in excel

thank you so much

I am new to vba so I was searching for some if statements

but I am not sure what I am doing

This is that you ask, with testing for non valid caharacters in graph title to use for filename.

Sub SaveCharts()
    Dim ws As Worksheet, chrtOb As Object, title, c As Long, p As Long, l As Long, ch As String
    Const notvalid = "<>:""/\|?*"
    l = Len(notvalid)
    For Each ws In ThisWorkbook.Worksheets
        For Each chrtOb In ws.ChartObjects
            title = vbNullString
            On Error Resume Next
            title = chrtOb.Chart.ChartTitle.Caption
            On Error GoTo 0
            If title = vbNullString Then
                title = chrtOb.Name
            Else
                For c = 1 To l
                    ch = Mid$(notvalid, c, 1)
                    p = 1
                    Do
                        p = InStr(p, title, ch)
                        If p <= 0 Then Exit Do
                        Mid$(title, p, 1) = "_"
                    Loop
                Next
            End If
            chrtOb.Chart.Export filename:=ThisWorkbook.Path & "\" & title & ".PNG", Filtername:="PNG"
        Next
    Next
    MsgBox "Charts Saved As Image File (png) in " & ThisWorkbook.Path
End Sub

This is a simpler version without checking... and use as filename the name of the chart.

Sub SaveCharts()
    Dim ws As Worksheet, chrtOb As Object
    
    For Each ws In ThisWorkbook.Worksheets
        For Each chrtOb In ws.ChartObjects
            chrtOb.Chart.Export filename:=ThisWorkbook.Path & "\" & chrtOb.Name & ".PNG", Filtername:="PNG"
        Next
    Next
    MsgBox "Charts Saved As Image File (png) in " & ThisWorkbook.Path
End Sub

This version accepts an optional parameter, the name of the sheet we want, if we don't give the parameter it checks all sheets

Sub SaveCharts(Optional wsName As String = vbNullString)
   Dim ws As Worksheet, chrtOb As Object, title, c As Long, p As Long, l As Long, ch As String, cnt as long
   Const notvalid = "<>:""/\|?*"
   For Each ws In ThisWorkbook.Worksheets
      If wsName = vbNullString Or ws.Name = wsName Then
         For Each chrtOb In ws.ChartObjects
             title = vbNullString
             On Error Resume Next
             title = chrtOb.Chart.ChartTitle.Caption
             On Error GoTo 0
             If title = vbNullString Then
                 title = chrtOb.Name
             Else
                 l = Len(notvalid)
                 For c = 1 To l
                     ch = Mid$(notvalid, c, 1)
                     p = 1
                     Do
                         p = InStr(p, title, ch)
                         If p <= 0 Then Exit Do
                         Mid$(title, p, 1) = "_"
                     Loop
                 Next
             End If
             chrtOb.Chart.Export filename:=ThisWorkbook.Path & "\" & title & ".PNG", Filtername:="PNG"
             cnt = cnt + 1
         Next
         If wsName <> vbNullString Then Exit For
      End If
   Next
   if cnt = 0 then
      MsgBox "No charts found to save!"
   else
      MsgBox cnt & " Charts Saved As Image File (png) in " & ThisWorkbook.Path
   End If
End Sub