VBA script won't run. Getting Run Time Error 424 Object required

I am getting a run time error when I try to run this. Can anyone solve this?

Sub recolor()
'Sub Color_Change

Dim rng As Range
Set rng = Range("A1:E16")

If Not Intersect(Target, rng) Is Nothing Then
    Dim cell As Range
    For Each cell In Intersect(Target, rng)
        Dim cellValue As String
        Dim rgbArray() As String
        cellValue = cell.Value
        rgbArray = Split(cellValue, ", ")
        If UBound(rgbArray) = 2 Then
            Dim red As Integer
            Dim green As Integer
            Dim blue As Integer
            red = CInt(rgbArray(0))
            green = CInt(rgbArray(1))
            blue = CInt(rgbArray(2))
            cell.Interior.Color = RGB(red, green, blue)
        End If
    Next cell
End If
End Sub

I am getting a Object required error

You don't need Target if you just want to process a fixed range:

Sub recolor()
    Dim cell As Range, arr
  
    For Each cell In ActiveSheet.Range("A1:E16").Cells 'or use a specific worksheet
        arr = Split(cell.Value, ",")
        If UBound(arr) = 2 Then
            cell.Interior.Color = _
              RGB(CLng(Trim(arr(0))), CLng(Trim(arr(1))), CLng(Trim(arr(2))))
        End If
    Next cell
End Sub