Save changes into new file without changing original. Rollback or edit a new file?

I have a macro that is replacing formulas in specific colored cells with values and then saves worksheet as a separate file. The problem - i don't want this changes to be applied to original file. So, the question - which way is better and easier to go? To save worksheet and then make changes, or rollback changes after new file is created?
I'm not very good with VBA, so code can be a little bit messy, sorry for that.

Sub Convertan()
Dim rng As Range
Dim formulaCell As Range
Set rng = ActiveSheet.UsedRange

'Check each colored cell in the range if it has a formula
For Each formulaCell In rng
If formulaCell.HasFormula Then
    If formulaCell.Interior.ColorIndex = 24 Then
    formulaCell.Formula = formulaCell.Value
    
    End If
End If
Next formulaCell

ActiveSheet.Copy ' Copies active sheet to a new workbook
ActiveWorkbook.SaveAs Range("B2").Value

End Sub

Export a Worksheet to a New Workbook

• Create a copy of the worksheet in a new workbook and process the copy leaving the original intact.

<!-- language: lang-vb -->

Sub Convertan()
    
    If ActiveSheet Is Nothing Then Exit Sub ' no visible workbooks open
    If Not TypeOf ActiveSheet Is Worksheet Then Exit Sub ' not a worksheet
    
    ActiveSheet.Copy
    
    Dim wb As Workbook: Set wb = Workbooks(Workbooks.Count)
    Dim ws As Worksheet: Set ws = wb.Worksheets(1)
    
    Dim urg As Range, cell As Range
    
    For Each cell In ws.UsedRange.Cells
        If cell.HasFormula Then
            If cell.Interior.ColorIndex = 24 Then
                If urg Is Nothing Then
                    Set urg = cell
                Else
                    Set urg = Union(urg, cell)
                End If
            End If
        End If
    Next cell
    
    If Not urg Is Nothing Then
        Dim arg As Range
        For Each arg In urg.Areas
            arg.Value = arg.Value
        Next arg
        'urg.Interior.ColorIndex = xlNone ' change the color
    End If
        
    Application.DisplayAlerts = False ' overwrite without confirmation
        wb.SaveAs ws.Range("B2").Value
    Application.DisplayAlerts = True
    
    Dim FilePath As String: FilePath = wb.FullName
    
    wb.Close SaveChanges:=False ' just got saved

    MsgBox "Worksheet exported to """ & FilePath & """.", vbInformation

End Sub