Add entries from a CSV into different arrays on awk and print them

I am making a .awk script and am taking in a .csv file containing product prices. The input file is:

Product,Price
EG412,25
EG411,15
EG516,55
EG517,60
LG210,10
LG180,5
HG915,95

I have already gotten an average through adding the second column and dividing by NR - 1, but now I am supposed to add products into arrays based upon if they are above or below the average price point. The issue I am running into is that my arrays are not printing and are also adding the top column of the csv containing "Product,Price". The code I have is:

BEGIN{
    FS=","
    sum=0
    avg=0
    high=0
    low=0
}
{
    sum+=$2
    total=NR-1
}
{
    avg=sum/total
}
{
    if ($2 > avg && NR > 1) {
        expensive[high] = $1
        high++
    } else if ($2 < avg && NR > 1) {
        cheap[low] = $1
        low++
    }
}
{
    for (i in expensive) {
        print i
        i++
    }
}
END{
    printf "Average Price: ""%.2\n", avg
}

I feel like I am doing this in an incredibly convoluted way, but I can't figure out how to get this to work. When I run it this way to test the array for only high value products, the result it returns is:

0
1
0
1
0
1
0
Average Price: 37.86

I would appreciate any help resolving this issue.

Use a 2-pass approach, first to calculate the average and then to determine which values are above/below the average:

$ cat tst.awk
BEGIN { FS="," }
FNR == 1 {
    next
}
NR == FNR {
    tot += $2
    ave = tot / (NR-1)
    next
}
{
    if ( $2 < ave ) {
        cheap[$1]
    }
    else if ( $2 > ave ) {
        expensive[$1]
    }
}
END {
    print "Average:", ave+0

    print "\nCheap:"
    for ( product in cheap ) {
        print product
    }

    print "\nExpensive:"
    for ( product in expensive ) {
        print product
    }
}

<p>

$ awk -f tst.awk file file
Average: 37.8571

Cheap:
LG180
LG210
EG411
EG412

Expensive:
EG516
EG517
HG915

You should calculate the average before hand, then pass it into your script, something like this should work:

calc.awk

# Arrays are 1-indexed
BEGIN { low = high = 1 }

NR == 1 { next }

$2  < avg { cheap[low++]      = $2 }
$2 >= avg { expensive[high++] = $2 }

END {
  printf "Average: %.2f\n", avg
  printf "Cheap:"
  for (i in cheap)
    printf " %d", cheap[i]
  printf "\nHigh:"
  for (i in expensive)
    printf " %d", expensive[i]
  printf "\n"
}

Run it like this:

awk -v avg=37.8571 -F, -f calc.awk infile.csv

Output:

Average: 37.86
Cheap: 25 15 10 5
High: 55 60 95